Пакетный файл: для / FL oop с Dsget возвращает только вторую строку, а не первую.

Question

setlocal ENABLEDELAYEDEXPANSION

For /F "tokens=1" %%g in ('cmd /c whoami') do (set loggedinusername=%%g)
set loggedinusername=%loggedinusername:~6%
echo %loggedinusername%


For /F "Tokens=1 eol==" %%a in ('dsquery user -samid %loggedinusername% ^|dsget user -dept ^|find /V "dept"') do (set deptname=%%a)

echo deptname equals %deptname%

Я надеялся, что кто-нибудь сможет взглянуть на этот небольшой фрагмент пакетного кода и сказать мне, если я ошибаюсь. Первая часть, захватывающая имя пользователя, работает нормально, и она успешно использует переменную во втором FOR /F.

Однако, как вы можете видеть в выводе ниже, она успешно находит название отдела, но когда я выведите переменную, она возвращает только сообщение об успешном выполнении dsget, а не строку выше.

Любая помощь или совет будут очень благодарны, Ура

C:\Users\*****\Desktop>for /F "Tokens=1 eol==" %a in ('dsquery user -samid USERNAME |dsget user -dept |find /V "dept"') do (set deptname=%a )

C:\Users\*****\Desktop>(set deptname=IT )

C:\Users\*****\Desktop>(set deptname=dsget )

C:\Users\*****\Desktop>echo deptname equals dsget
deptname equals dsget`

Answer 1

Есть много вариантов, доступных вам, однако, поскольку я не могу использовать эти команды или видеть фактический результат, который вы получаете, вам придется использовать или адаптировать один из следующих примеров.

Если бы вы знали, что название отдела никогда не будет начинаться с символа d, вы могли бы просто использовать:

For /F "EOL=d Delims=" %%G In ('dsquery user -samid USERNAME ^| dsget user -dept') Do Set "deptname=%%G"

Однако, если название отдела может начинаться с d, вы можно использовать дополнительную команду find:

For /F Delims^=^ EOL^= %%G In ('dsquery user -samid USERNAME ^| dsget user -dept ^| find /v "dept" ^| find /v "dsget"') Do Set "deptname=%%G"

Или использовать вместо нее команду findstr:

For /F Delims^=^ EOL^= %%G In ('dsquery user -samid USERNAME ^| dsget user -dept ^| findstr /v "dept dsget"') Do Set "deptname=%%G"

В качестве альтернативы вы можете использовать идею, которую я предоставил в разделе комментариев:

Set "deptname="
For /F Delims^=^ EOL^= %%G In ('dsquery user -samid USERNAME ^| dsget user -dept ^| find /v "dept"') Do If Not Defined deptname Set "deptname=%%G"

Другие возможные альтернативы могут включать:

Если первая строка всегда является отделом:

For /F Skip^=1^ Delims^=^ EOL^= %%G In ('dsquery user -samid USERNAME ^| dsget user -dept') Do Set "deptname=%%G" & GoTo Next
:Next

Если есть пустая первая строка и вторая строка равно dept, затем замените Skip^=1^ на Skip^=2^

Если бы вы знали все названия отделов, вы могли бы также поместить их в соответствие findstr:

Set "depts=Design Finance IT Workshop"
For /F Delims^=^ EOL^= %%G In ('dsquery user -samid USERNAME ^| dsget user -dept ^| findstr /i "%depts%"') Do Set "deptname=%%G"