Быстрее ли добавить строку с substr? - PullRequest
Новая
       107

Быстрее ли добавить строку с substr?

6 голосов
/ 08 мая 2020

Я только что нашел код, который начинается с substr( $str, 0, 0, $prepend )

my $foo = " world!"
substr( $foo, 0, 0, "Hello " );

Это быстрее, чем 

my $foo = " world!"
$foo = "Hello $foo";

1 Ответ

5 голосов
/ 08 мая 2020

Optrees

Если мы сравним два optrees, верхний имеет 

b     <@> substr[t2] vK/4 ->c
-        <0> ex-pushmark s ->7
7        <0> padsv[$foo:2,3] sM ->8
8        <$> const[IV 0] s ->9
9        <$> const[IV 0] s ->a
a        <$> const[PV "Hello "] s ->b

В то время как нижний имеет 

8     <+> multiconcat(" world!",-1,7)[$foo:2,3] sK/TARGMY,STRINGIFY ->9
-        <0> ex-pushmark s ->7
7        <0> padsv[$foo:2,3] s ->8

Benchmarking

I ' Мы создали для этого быстрый тест, 

use Benchmark;
use strict;
use warnings;

sub b_multiconcat {
    my $foo = "world!";
    $foo = "Hello $foo";
    return $foo;
}

sub b_substr {
    my $foo = "world!";
    substr( $foo, 0, 0, "Hello " );
    return $foo;
}

sub b_substr_lvalue {
    my $foo = "world!";
    substr( $foo, 0, 0 ) = "Hello ";
    return $foo;
}

unless ( b_multiconcat() eq b_substr() && b_substr() eq b_substr_lvalue() ) {
    die "they're not all the same";
}

Benchmark::cmpthese( -3, {
    multiconcat   => \&b_multiconcat,
    substr        => \&b_substr,
    substr_lvalue => \&b_substr_lvalue
} );

И результаты, которые я получил, следующие: 

               Rate              substr    substr_valute   multiconcat
substr         7830854/s            --          -18%          -24%
substr_lvalue  9606148/s           23%            --           -7%
multiconcat   10288066/s           31%            7%            --

Итак, мы видим, что multiconcat экономит несколько операций и работает несколько быстрее. Также гораздо приятнее будет сказать: 

$foo = "Hello $foo";
...