Как я могу добавить тег в AWS EBS при создании через EC2 с Terraform? - PullRequest
Новая
       24

Как я могу добавить тег в AWS EBS при создании через EC2 с Terraform?

1 голос
/ 19 июня 2020

Я пытаюсь создать экземпляр EC2 для тестовой среды, в которой используется AMI PROD. Все создается правильно, но я не могу добавить, как добавить теги к томам EBS, которые создаются вместе с ним?

Теги работают на EC2, но не применяются к тому EBS или root. Я попытался добавить карту тегов и для них, но это было недопустимо. Любые идеи? 

provider "aws" {
  region = "us-east-1"
}

data "aws_ami" "existing_sft_ami" {
  most_recent = true

  filter {
    name   = "name"
    values = [var.prod_name]
  }
  owners = [
    var.aws_account_id]
}

data "aws_subnet" "subnet" {
  id = var.aws_subnet_id
}

resource "aws_instance" "sftp" {
  ami           = data.aws_ami.existing_sft_ami.id
  instance_type = "t2.micro"
  availability_zone = var.availability_zone
  subnet_id = data.aws_subnet.subnet.id
  key_name = var.ssh_key_name
  vpc_security_group_ids = [var.aws_security_group_id]
  root_block_device {
    delete_on_termination = true
  }
  ebs_block_device {
    device_name = "/dev/sdb"
    delete_on_termination = true
  }
  tags = {
    Name = var.name
    Owner = var.owner
    Created = formatdate("DD MMM YYYY hh:mm ZZZ", timestamp())
    Environment = "TEST"
  }
}

1 Ответ

1 голос
/ 19 июня 2020

Вам необходимо использовать дополнительный аргумент volume_tags, чтобы пометить тома. Кроме того, чтобы сделать ваш код немного больше DRY, вы можете сделать это с помощью блока locals. 

locals {
    tags = {
        Name = var.name
        Owner = var.owner
        Created = formatdate("DD MMM YYYY hh:mm ZZZ", timestamp())
        Environment = var.environment
    }
}

resource "aws_instance" "sftp" {
  ami           = data.aws_ami.existing_sft_ami.id
  instance_type = "t2.micro"
  availability_zone = var.availability_zone
  subnet_id = data.aws_subnet.subnet.id
  key_name = var.ssh_key_name
  vpc_security_group_ids = [var.aws_security_group_id]
  root_block_device {
    delete_on_termination = true
  }
  ebs_block_device {
    device_name = "/dev/sdb"
    delete_on_termination = true
  }
  tags = local.tags
  volume_tags = local.tags
}
...