Вставка тега XSLT

Question

У меня есть многоуровневый блок XML, мое требование - добавить новый тег Scenario для каждого блока Employee. Значение в новом теге сценария может изменяться в зависимости от значения в теге события

FROM

<Extract>
    <Header>
        <Date1>01/01/2020</Date1>
    </Header>
    <Employee>
        <Status>
            <Event>Event_1</Event>
        </Status>
    </Employee>
    <Employee>
        <Status>
            <Event>Event_2</Event>
        </Status>
    </Employee>
</Extract>

TO

<Extract>
    <Header>
        <Date1>01/01/2020</Date1>
    </Header>
    <Employee>
        <Status>
            <Event>Event_1</Event>
        </Status>
        <Scenario>A</Scenario>
    </Employee>
    <Employee>
        <Status>
            <Event>Event_2</Event>
        </Status>
        <Scenario>B</Scenario>
    </Employee>
</Extract>

Я играл с этим , Я могу успешно вставить тег, но перед добавлением тега мне нужен оператор выбора для определения желаемого результата в теге. Как показано ниже

<xsl:param name="to-insert"> 
    <xsl:choose>
        <xsl:when test="Employee/Status/Event = 'Event_1' ">
                <Scenairo>A</Scenairo>
        </xsl:when>
        <xsl:when test="Employee/Status/Event = 'Event_2' ">
                <Scenairo>B</Scenairo>
        </xsl:when>
        <xsl:otherwise>
            <Scenairo><xsl:value-of select="'no scenario mapped'"/></Scenairo>
        </xsl:otherwise>
    </xsl:choose>
</xsl:param>

<!-- Copy all sections of XML -->
<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
</xsl:template>

<xsl:template match="Employee">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/> 
         <xsl:copy-of select="$to-insert"/>
    </xsl:copy>
</xsl:template>

Answer 1

всегда попадает в xsl: иначе

Нет, но он оценивает только первого Employee (в XSLT 1.0) или всех сотрудников вместе (в XSLT 2.0).

Если у вас может быть более одного Employee, вам необходимо вычислить значение Scenario из контекста Employee - например:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Employee">
    <xsl:copy>
        <xsl:apply-templates/>
        <Scenario>
            <xsl:choose>
                <xsl:when test="Status/Event = 'Event_1'">A</xsl:when>
                <xsl:when test="Status/Event = 'Event_2'">B</xsl:when>
                <xsl:otherwise>no scenario mapped</xsl:otherwise>
            </xsl:choose>
        </Scenario>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>