Сохранять определенные теги HTML во время XSLT

Question

Я искал решения для стека потока, но ни одно из них, похоже, не работает для меня Вот мой вопрос Допустим, у меня есть следующий текст:

Источник:

<greatgrandparent>
<grandparent>
    <parent>
         <sibling>
              Hey, im the sibling .
          </sibling>
        <description>
        $300$ <br/> $250 <br/> $200! <br/> <p> Yes, that is right! <br/> You can own a ps3 for only $200 </p>
        </description>
    </parent>
    <parent>
         ... (SAME FORMAT)
    </parent>
       ... (Several more parents)
</grandparent>
</greatgrandparent>

Выход:

 <newprice>
        $300$ <br/> $250 <br/> $200! <br/> Yes, that is right! <br/> You can own a ps3 for only $200  
    </newprice>

Я не могу найти способ сделать это.

Текущий XSL:

    <xsl:template match="/">
            <xsl:apply-templates />
        </xsl:template>

        <xsl:template match="greatgrandparents">
            <xsl:apply-templates />
        </xsl:template>

    <xsl:template match = "grandparent">

    <xsl:for-each select = "parent" >
          <newprice>
             <xsl:apply-templates>
           </newprice>
    </xsl:for-each>
    </xsl:template> 

<xsl:template match="description"> 
    <xsl:element name="newprice"> 
       <xsl:apply-templates/> 
    </xsl:element> 
</xsl:template> 

<xsl:template match="p"> 
   <xsl:apply-templates/> 
</xsl:template> 

Answer 1

Использование шаблонов для определения поведения определенных элементов

<!-- after standard identity template -->

<xsl:template match="description">
    <xsl:element name="newprice">
       <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

<xsl:template match="p">
   <xsl:apply-templates/>
</xsl:template>

Первый шаблон говорит, что нужно поменять description на newprice. Второй говорит игнорировать элемент p.

Если вы не знакомы с шаблоном идентификации, посмотрите здесь , чтобы найти несколько примеров.

РЕДАКТИРОВАТЬ : Учитывая новый пример, мы видим, что вы хотите извлечь только элемент описания и его содержимое. Обратите внимание, что действие шаблона начинается с шаблона match="/". Мы можем использовать этот элемент управления там, где начинается наша таблица стилей, и таким образом пропустить большую часть риффрафа, который мы хотим отфильтровать.

измените <xsl:template match="/"> на что-то более похожее на:

    <xsl:template match="/">
        <xsl:apply-templates select="//description"/>   
        <!-- use a more specific XPath if you can -->
    </xsl:template>

Итак, в целом наше решение выглядит так:

<xsl:stylesheet 
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0"
    exclude-result-prefixes="xs">

<xsl:template match="/">
    <xsl:apply-templates select="//description" />
</xsl:template>

<!-- this is the identity template -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="description">
    <xsl:element name="newprice">
       <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

<xsl:template match="p">
   <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

Answer 2

Вероятно, самое короткое решение это :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="description">
   <newprice>
     <xsl:copy-of select="node()"/>
   </newprice>
 </xsl:template>

 <xsl:template match="text()[not(ancestor::description)]"/>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу, получается желаемый результат:

<newprice>
        $300$ <br /> $250 <br /> $200! <br /> <p> Yes, that is right! <br /> You can own a ps3 for only $200 </p>
        </newprice>

Примечание :

1. Использование <xsl:copy-of select="node()"/> для копирования всего поддерева, укорененного в description, без самого корня.

2. Как мы переопределяем (с определенным пустым шаблоном) встроенный шаблон XSLT , предотвращая любые текстовые узлы, которые не являются потомками элемента <description> , для вывода.

Answer 3

Вы должны посмотреть на xsl:copy-of.

Скорее всего, вы получите что-то вроде:

<xsl:template match="description">
    <xsl:copy-of select="."/>
</xsl:template>

Answer 4

Разве содержимое не должно быть внутри элемента CDATA? И тогда, вероятно, отключите выходную кодировку для xsl: value-of ..