Как приложение Delphi может определить настройки сетевого прокси на ПК с Windows?

Question

У меня есть приложение Delphi, которое связывается с веб-серверами в Интернете с помощью Indy компонентов . Большинство пользователей приложения имеют прямые подключения к Интернету, но некоторые находятся за прокси-сервером локальной сети. Я не хочу просить пользователей искать свой прокси-сервер в диалоговом окне Свойства обозревателя / Подключения / Параметры локальной сети

альтернативный текст http://toybase.files.wordpress.com/2008/11/ie-proxy-settings.png

как откровенно говоря, большинство людей не будут знать или беспокоиться о том, что это за настройка.

Могу ли я получить эту информацию через некоторые системные вызовы из приложения Delphi-7?

Большое спасибо!

Answer 1

Через WinAPI - WinHttpGetIEProxyConfigForCurrentUser . Вы должны любить длинные имена WINAPI MS ^ _ ^.

После редактирования OP: Вы можете прочитать из реестра, AFAIR он будет находиться здесь:

 [ HKEY_CURRENT_USER/Software/Microsoft/Windows/CurrentVersion/Internet Settings ]

Answer 2

Вот еще один метод, который я использую, который не требует прямого доступа к реестру.Это работает под D2007, но я не могу понять, почему это не будет работать под D7.

uses
  WinInet,
  SysUtils;

function UseIEProxyInfo(var ProxyHost: String; var ProxyPort: Integer): Boolean;
var
  ProxyInfo: PInternetProxyInfo;
  Len: LongWord;
  ProxyDetails: String;
  s2: String;
  i1: Integer;

  procedure RemoveProtocol(var str: string);
  var
    i1 : integer;
  begin
    i1 := PosText('://', str);
    if i1 > 0 then
      Delete(str, 1, i1 + 2);
    i1 := PosText('http=', str);
    if i1 > 0 then begin
      Delete(str, 1, i1 + 4);
      str := SubStr(str, 1, ' ');
    end;
  end;

begin
  Result := False;

  Len := 4096;
  GetMem(ProxyInfo, Len);
  try
    if InternetQueryOption(nil, INTERNET_OPTION_PROXY, ProxyInfo, Len) then
    begin
      if ProxyInfo^.dwAccessType = INTERNET_OPEN_TYPE_PROXY then
      begin
        Result := True;
        ProxyDetails := ProxyInfo^.lpszProxy;

        RemoveProtocol(ProxyDetails);
        s2 := SubStr(ProxyDetails, 2, ':');
        if s2 <> '' then
        begin
          try
            i1 := StrToInt(s2);
          except
            i1 := -1;
          end;

          if i1 <> -1 then
          begin
            ProxyHost := SubStr(ProxyDetails, 1, ':');
            ProxyPort := i1;
          end;
        end;
      end;
    end;
  finally
    FreeMem(ProxyInfo);
  end;
end;

Answer 3

Код Delphi для Корнел Киселевич ответ :

uses Registry, Windows;

function detectIEProxyServer() : string;
begin
  with TRegistry.Create do
    try
        RootKey := HKEY_CURRENT_USER;
        if OpenKey('\Software\Microsoft\Windows\CurrentVersion\Internet Settings', False) then begin
          Result := ReadString('ProxyServer');
          CloseKey;
        end
        else
          Result := '';
    finally
      Free;
    end;
end;

Answer 4

Вы должны будете получить настройки прокси из браузера, которые могут находиться в нескольких разных местах в зависимости от используемого браузера.

Возможно, вы рассмотрите Протокол автообнаружения веб-прокси , который автоматически определяет настройки прокси в сети.