Условные шаблоны на основе глобальной переменной

Question

Я хочу скопировать большую часть XML как есть, за исключением пары узлов, которые зависят от компании, которая будет передана в таблицу стилей. Если у меня есть шаблон идентификации, и я хочу, чтобы что-то происходило, только если глобальная переменная равна определенному значению, как мне это сделать, поскольку вы не можете поставить проверку на совпадение между [] ... по крайней мере в 1.0? Поэтому в приведенном ниже примере я хочу поменять название компании только тогда, когда переменная равна некоторому значению, например «DEF Company». Переменная 'company' не будет частью XML.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"><br> <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="no"/>
<!-- Dummy example variable -->
<xsl:variable name="company"><xsl:text>DEF Company</xsl:text></xsl:variable>

<xsl:template match="node() | @*">  
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>  
    </xsl:copy>  
</xsl:template>  

<xsl:template match="Company">  
    <xsl:copy>  
        <xsl:text>ABC Company</xsl:text>  
    </xsl:copy>  
</xsl:template>

</xsl:stylesheet>

Answer 1

Ну, вы можете проверить внутри матча. Это может быть не самым элегантным, но это должно работать.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:param name="company" select="'DEF Company'"/>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Company">
        <xsl:copy>
            <xsl:choose>
                <xsl:when test="$company = 'DEF Company'">
                    <xsl:text>ABC Company</xsl:text>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="@* | node()" />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Для этой цели я бы лучше использовал встроенный элемент в таблице стилей:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:my="my-own-namespace">
    <my:company match="DEF Company" replace="ABC Company" />
    <xsl:template match="Company[.=document('')/*/my:company/@match]">
        <xsl:copy>
            <xsl:value-of select="document('')/*/my:company/@replace" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template> 
</xsl:stylesheet>

Функция document () с параметром пустой строки ссылается на сам корень таблицы стилей.

Answer 3

Я использую [] с шаблоном соответствия и механизмом XSLT версии 1.0 (Xalan).

Например:

<xsl:template match="@*|node()[name() !='a']">