Как преобразовать XML с сохранением xslt <br /> и не сохранять другие теги в тексте

Question

Этот вопрос очень похож на this . За исключением того, что я хочу сохранить только <br /> и некоторые теги <img> (с class = "visible"). Т.е. от:

<example>
   <text>
      Some text with <br /> and <img src="source" /> then text .... <img class="visible" src="source" />
   </text>
</example>

Иметь:

 <div class="example"> 
  <p>Some text with <br /> and then text ....  <img class="visible" src="source" /></p> 
 </div>

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="example">
   <div class="example">
    <xsl:apply-templates/>
   </div>
 </xsl:template>

 <xsl:template match="example/text">
   <p><xsl:apply-templates/></p>
 </xsl:template>

 <xsl:template match=
  "example/text/*
          [not(self::br)
         and
           not(self::img[@class='visible'])
          ]"/>
</xsl:stylesheet>

при применении к предоставленному XML-документу дает требуемый, правильный результат :

<div class="example"><p>
      Some text with <br/> and  then text .... <img class="visible" src="source"/></p></div>

Answer 2

Я не проверял это, но я думаю, что это должно помочь вам.

<xsl:template match="/example/text">
  <div class="example">
    <p>
      <xsl:copy-of select="@* | node()[name()='br' or (name()='img' and @class='visible')]"/>
    </p>
  </div>
</xsl:template>