Можно ли обнаружить наличие тега (xml) с помощью XSLT?

Question

Я предполагаю проверить наличие тега и создать новый узел в соответствии с результатом ..

Это входной XML:

<root> 
  <tag1>NS</tag1> 
  <tag2 id="8">NS</tag2> 
  <test> 
    <other_tag>text</other_tag> 
    <main>Y</main> 
  </test> 
  <test> 
    <other_tag>text</other_tag> 
  </test> 
</root> 

И требуемый выходной XML:

<root> 
  <tag1>NS</tag1> 
  <tag2 id="8">NS</tag2> 
  <test> 
    <other_tag>text</other_tag> 
    <Main_Tag>Present</Main_Tag> 
  </test> 
  <test> 
    <other_tag>text</other_tag> 
    <Main_Tag>Absent</Main_Tag>
  </test> 
</root> 

Я знаю, чтобы проверить значение тега, но это что-то новое для меня.

Я пытался использовать этот шаблон: (который не работает согласно требованию)

   <xsl:template match="test"> 
      <xsl:element name="test"> 
        <xsl:for-each select="/root/test/*"> 
      <xsl:choose> 
        <xsl:when test="name()='bbb'"> 
          <xsl:element name="Main_Tag"> 
            <xsl:text>Present</xsl:text> 
          </xsl:element> 
        </xsl:when> 
        <xsl:otherwise> 
          <xsl:element name="Main_Tag"> 
          <xsl:text>Absent</xsl:text> 
          </xsl:element> 
        </xsl:otherwise> 
      </xsl:choose> 
        </xsl:for-each> 
      </xsl:element> 
  </xsl:template> 

Answer 1

Как насчет этого:

<xsl:choose>
    <xsl:when test="main = 'Y'">
        <Main_Tag>Present</Main_Tag> 
    </xsl:when>
    <xsl:otherwise>
        <Main_Tag>Absent</Main_Tag>
    </xsl:otherwise>
</xsl:choose>

Или

<Main_Tag>
    <xsl:choose>
        <xsl:when test="main = 'Y'">Present</xsl:when>
        <xsl:otherwise>Absent</xsl:otherwise>
    </xsl:choose>
</Main_Tag>

Answer 2

Я не утверждаю, что это лучше - для этой проблемы я бы, вероятно, сделал это именно так, как описывает Рубенс Фариас, - но это показывает другой подход к проблеме, который может быть полезен в более сложных ситуациях. Я обнаружил, что чем больше логики я вкладываю в сопоставление с шаблоном, тем более гибкими и расширяемыми мои преобразования оказываются в долгосрочной перспективе. Итак, добавьте их в преобразование идентичности:

<xsl:template match="test/main">
   <Main_Tag>present</Main_Tag>
</xsl:template>

<xsl:template match="test[not(main)]">
   <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
      <Main_Tag>absent</Main_Tag>
   </xsl:copy>
</xsl:copy>

Answer 3

Расширение второго ответа Рубенса Фариаса ...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <!--Identity transform-->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>   

    <!--Add <Main_Tag>Present</Main_Tag> or <Main_Tag>Absent</Main_Tag>.-->
    <xsl:template match="test">
        <xsl:copy>
           <xsl:apply-templates select="@*|node()"/>
           <Main_Tag>
                <xsl:choose>
                    <xsl:when test="main = 'Y'">Present</xsl:when>
                    <xsl:otherwise>Absent</xsl:otherwise>
                </xsl:choose>
            </Main_Tag>
        </xsl:copy>
    </xsl:template>

     <!--Remove all <main> tags-->
    <xsl:template match="main"/>       
</xsl:stylesheet>

Answer 4

Вы можете использовать функцию подсчета Xpath , чтобы увидеть, существует ли узел main (count(name) = 0) и вывести соответственно.