Отделение положительных значений от «нулевых» значений в XSLT для каждого оператора

Question

Я просматриваю XML-файл (который содержит несколько таблиц), используя XSLT. Часть работы страницы состоит в том, чтобы получить заголовок каждой таблицы и представить этот заголовок вместе с количеством элементов, содержащихся в этой таблице (т. Е. "Проблемы (5)").

Я могу получить количество элементов, но теперь мне нужно разделить разделы с 0 (нулем) элементов в них и поместить их внизу списка названий таблиц. У меня возникли проблемы с этим, потому что другие элементы с положительными числами должны быть оставлены в их первоначальном порядке / не отсортированы.

Вот код для списка названий:

<ul>
  <xsl:for-each select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title">
     <li style="list-style-type:none;">
     <div style = "padding:3px"><a href="#{generate-id(.)}">
     <xsl:variable name ="count" select ="count(../n1:entry)"/>
     <xsl:choose>
        <xsl:when test = "$count != 0">
           <xsl:value-of select="."/> (<xsl:value-of select="$count"/>)
        </xsl:when>
        <xsl:otherwise>
           <div id = "zero"><xsl:value-of select="."/> (<xsl:value-of select="$count"/>)</div>
        </xsl:otherwise>
     </xsl:choose>
     </a>
     </div>
     </li>
   </xsl:for-each>
</ul>

Прямо сейчас "нулевой" div просто помечает каждую ссылку серым цветом.

Любая помощь, касающаяся того, как поместить «нулевые» делители внизу списка, будет принята с благодарностью. Спасибо!

Отредактированный код с использованием нулевых / ненулевых шаблонов:

<xsl:for-each select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title">
   <li style="list-style-type:none;">
      <div style = "padding:3px"><a href="#{generate-id(.)}">
         <xsl:apply-templates select="n1:title[count(../n1:entry) != 0]" mode="nonzero" />
         <xsl:apply-templates select="n1:title[count(../n1:entry) == 0]" mode="zero" />
      </a>
      </div>
   </li>
</xsl:for-each>

Answer 1

Вы, наверное, довольны тем, что у вас есть, но мне понравился ответ Димитра, и я хотел, чтобы это сработало только для моего собственного обучения.

Я упростил (я считаю, что это) входные данные:

<component>
  <section>
    <title>table 1</title>
    <entry/>
  </section>
  <section>
    <title>table 2</title>
  </section>
  <section>
    <title>table 3</title>
    <entry/>
    <entry/>
  </section>
</component>

и полученная таблица стилей:

<xsl:stylesheet
    version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="html" indent="yes"/>

  <xsl:template match="/component">
    <ul>
      <xsl:apply-templates select="section">
        <xsl:sort select="count(entry) = 0"/>
      </xsl:apply-templates>
    </ul>
  </xsl:template>

  <xsl:template match="section[entry]">
    <li>
      <xsl:value-of select="title"/>
      <xsl:text> (</xsl:text>
      <xsl:value-of select="count(entry)"/>
      <xsl:text>)</xsl:text>
    </li>
  </xsl:template>

  <xsl:template match="section[not(entry)]">
    <li>
      <div id="zero"><xsl:value-of select="title"/></div>
    </li>
  </xsl:template>
</xsl:stylesheet>

Вот вывод, который я получаю:

<ul>
   <li>table 1 (3)</li>
   <li>table 3 (2)</li>
   <li>
      <div id="zero">table 2</div>
   </li>
</ul>

Еще раз спасибо Димитру за предложение, которое он сделал. Мне нравится <xsl:apply-templates/> над <xsl:for-each/>, потому что они чувствуют себя в духе декларативности XSL и немного более неудобны для меня из-за обязательного опыта написания скриптов и программирования.

Спасибо,
Zachary

Answer 2

Вы должны пройти их отдельно. Вы можете сделать это, используя xsl:apply-templates вместо xsl:for-each

<xsl:template match=".... something ....">
  <ul>
    <xsl:apply-templates select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title[count(../n1:entry) != 0]"/>
    <xsl:apply-templates select="n1:component/n1:structuredBody/n1:component/n1:section/n1:title[count(../n1:entry) = 0]"/>
  </ul>

</xsl:template>

<xsl:template match="n1:title" >
  <li style="list-style-type:none;">
    <div style = "padding:3px"><a href="#{generate-id(.)}">
      <xsl:variable name ="count" select ="count(../n1:entry)"/>
      <xsl:choose>
        <xsl:when test = "$count != 0">
          <xsl:value-of select="."/> (<xsl:value-of select="$count"/>)
        </xsl:when>
        <xsl:otherwise>
          <div id = "zero"><xsl:value-of select="."/> (<xsl:value-of select="$count"/>)</div>
        </xsl:otherwise>
      </xsl:choose>
    </a>
    </div>
  </li>

</xsl:template>

Answer 3

Нет mode необходимо и нет условной логики (<xsl:choose>).

Кроме того, преобразование может использовать только один <xsl:apply-templates>:

<xsl:apply-templates select="n1:title>
  <xsl:sort select="count(../n1:entry) = 0" data-type="number"/>
</xsl:apply-templates>

Вот два шаблона для использования :

<!-- There is one or more ../n1:entry -->
<xsl:template match="n1:title"[../n1:entry] >  
  ...  
</xsl:template> 

<!-- No ../n1:entry exists --> 
<xsl:template match="n1:title"[not(../n1:entry)]">  
  ...  
</xsl:template> 

Answer 4

Вы можете создать два шаблона для обработки узлов с атрибутом mode на каждом.A mode="zero" и mode="nonzero", если хотите.

<xsl:template match="n1:title" mode="zero">
  ...
</xsl:template>
<xsl:template match="n1:title" mode="nonzero">
  ...
</xsl:template>

Вызовите шаблон nonzero, выбрав элементы с count > 0 и шаблон zero с count = 0.

<xsl:apply-templates select="n1:title[count(../n1:entry) &gt; 0]" mode="nonzero" />
<xsl:apply-templates select="n1:title[count(../n1:entry) = 0]" mode="zero" />

Поместите вызов на шаблон nonzero над вызовом на шаблон zero.