XSLT многократная замена

Question

У меня есть документ XML, что-то вроде

<root>
  <item>_x0034_SOME TEXT</item>
  <item>SOME_x0020_TEXT</item>
  <item>SOME_x0020_TEXT_x0032_</item>
</root>

Я экспортирую его в HTML, но у меня возникают проблемы с заменой escape-символов. В Интернете я нашел несколько шаблонов для замены текста, но все они похожи на это:

<xsl:template name="replaceString">
    <xsl:param name="strOrig"/>
    <xsl:param name="strSearch"/>
    <xsl:param name="strReplace"/>
    <xsl:choose>
        <xsl:when test="contains($strOrig, $strSearch)">
            <xsl:value-of select="substring-before($strOrig, $strSearch)"/>
            <xsl:value-of select="$strReplace"/>
            <xsl:call-template name="replaceString">
                <xsl:with-param name="strOrig" select="substring-after($strOrig, $strSearch)"/>
                <xsl:with-param name="strSearch" select="$strSearch"/>
                <xsl:with-param name="strReplace" select="$strReplace"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$strOrig"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Я не уверен, как я могу использовать это, чтобы сделать несколько замен. Я пробовал это:

<xsl:for-each select="PinnacleSys.PMC.Plugins.PVR.PvrChannelDescriptorWrapper/PinnacleSys.PMC.Plugins.PVR.DVBTPvrChannelDescriptor">

    <!--name="<xsl:value-of select="replace(replace(Name, '_x0020_', ' '), '_x0034_', '3')"/>" -->
    <!--name="<xsl:value-of select="Name"/>"-->
    <xsl:variable name="var1" select="Text" />
        <xsl:value-of select="replace($FeatureInfo,'Feature=','TESTING')"/>

    name="
        <xsl:call-template name="replaceString">
            <xsl:with-param name="strOrig" select="Name"/>
            <xsl:with-param name="strSearch" select="'_x0020_'"/>
            <xsl:with-param name="strReplace" select="' '"/>
        </xsl:call-template>
        <xsl:call-template name="replaceString">
            <xsl:with-param name="strOrig" select="Name"/>
            <xsl:with-param name="strSearch" select="'_x0030_'"/>
            <xsl:with-param name="strReplace" select="'0'"/>
        </xsl:call-template>
       ..."

Но это просто объединяет строку несколько раз, каждый со своей заменой. Я также исследовал переменные; если бы я мог присвоить результат вызова шаблона переменной, я мог бы получить грязное, но работающее решение, которого мне достаточно. Однако я не смог и не знаю, возможно ли это.

Какой лучший способ сделать это?

Я ограничен 1.0 XSLT (с 2.0 я мог бы вызвать один replace () внутри другого).

Answer 1

Для собственного решения XSLT 1.0, использующего шаблон для замены, отдельные замены должны быть вложенными, как показано здесь. Это явно не эффективно из-за потенциального количества замен. Оптимизированная версия приведена ниже.

<xsl:template match="item">
<xsl:copy>
    <xsl:call-template name="replace-substring">
        <xsl:with-param name="original">
            <xsl:call-template name="replace-substring">
                <xsl:with-param name="original">
                    <xsl:call-template name="replace-substring">
                        <xsl:with-param name="original" select="."/>
                        <xsl:with-param name="substring" select="'_x0020_'"/>
                        <xsl:with-param name="replacement" select="' '"/>
                    </xsl:call-template>
                </xsl:with-param>
                <xsl:with-param name="substring" select="'_x0032_'"/>
                <xsl:with-param name="replacement" select="'2'"/>
            </xsl:call-template>
        </xsl:with-param>
        <xsl:with-param name="substring" select="'_x0034_'"/>
        <xsl:with-param name="replacement" select="'4'"/>
    </xsl:call-template>
</xsl:copy>
</xsl:template>

<xsl:template name="replace-substring">
<xsl:param name="original"/>
<xsl:param name="substring"/>
<xsl:param name="replacement" select="''"/>
<xsl:choose>
    <xsl:when test="contains($original, $substring)">
        <xsl:value-of select="substring-before($original, $substring)"/>
        <xsl:copy-of select="$replacement"/>
        <xsl:call-template name="replace-substring">
            <xsl:with-param name="original" select="substring-after($original, $substring)"/>
            <xsl:with-param name="substring" select="$substring"/>
            <xsl:with-param name="replacement" select="$replacement"/>
        </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="$original"/>
    </xsl:otherwise>
</xsl:choose>
</xsl:template>

Поскольку выводом является HTML (XML тоже подойдет), строки _xNNNN_ можно преобразовать в их шестнадцатеричные ссылки на символы, например, &#xNNNN;. Этот шаблон эффективен.

<xsl:template match="item">
<xsl:copy>
    <xsl:call-template name="replaceChars">
        <xsl:with-param name="original" select="."/>
    </xsl:call-template>
</xsl:copy>
</xsl:template>

<xsl:template name="replaceChars">
<xsl:param name="original"/>
<xsl:choose>
    <xsl:when test="contains($original, '_x')">
        <xsl:value-of select="substring-before($original, '_x')"/>
        <xsl:variable name="after" select="substring-after($original, '_x')"/>
        <xsl:variable name="char" select="substring-before($after, '_')"/>
        <xsl:value-of select="concat('&amp;#x',$char,';')" disable-output-escaping="yes"/>
        <xsl:call-template name="replaceChars">
            <xsl:with-param name="original" select="substring-after($after, '_')"/>
        </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="$original"/>
    </xsl:otherwise>
</xsl:choose>
</xsl:template>

Это результирующий вывод.

<root>
    <item>&#x0034;SOME TEXT</item>
    <item>SOME&#x0020;TEXT</item>
    <item>SOME&#x0020;TEXT&#x0032;</item>
</root>

Answer 2

Разместить вызов шаблона внутри тела переменной.

<xsl:variable name="myVar"><xsl:call-template name="replaceString">
        <xsl:with-param name="strOrig" select="Name"/>
        <xsl:with-param name="strSearch" select="'_x0020_'"/>
        <xsl:with-param name="strReplace" select="' '"/>
    </xsl:call-template>
</xsl:variable>

Это присваивает myVar содержимое вызова.

Answer 3

Посмотрите на поддержку регулярных выражений в EXSLT (www.exslt.org). Поддержка EXSLT доступна в большинстве современных процессоров XSL.

Answer 4

XSLT 1.0 - не самый лучший способ замены строк. Шаблон, который у вас есть, будет использоваться. Однако для замены строк я использую замену строк на другом языке, обычно на JavaScript или C # / VB.NET (Java или любой другой язык тоже подойдет). Предположительно, в какой-то момент документ XML сериализуется в строку. Как только это строка, используйте простое замещение строки или регулярные выражения для более сложного сопоставления с образцом.