в tcl, как заменить строку в файле? - PullRequest
Новая
       47

в tcl, как заменить строку в файле?

4 голосов
/ 12 мая 2010

скажем, я открыл файл, а затем проанализировал его в строки. Тогда я использую цикл: 

foreach line $lines {}

внутри цикла, для некоторых строк я хочу заменить их внутри файла другими строками. Является ли это возможным? Или мне нужно записать другой временный файл, а затем заменить файлы, когда я закончу?

например, если файл содержал 

AA
BB

и затем я заменяю заглавные буквы строчными буквами, я хочу, чтобы исходный файл содержал 

aa
bb

Спасибо!

Ответы [ 5 ]

8 голосов
/ 12 мая 2010

для простых текстовых файлов наиболее безопасно переместить исходный файл в «резервное» имя, а затем переписать его, используя исходное имя файла:

Обновление: отредактировано на основе отзывов Донала 

set timestamp [clock format [clock seconds] -format {%Y%m%d%H%M%S}]

set filename "filename.txt"
set temp     $filename.new.$timestamp
set backup   $filename.bak.$timestamp

set in  [open $filename r]
set out [open $temp     w]

# line-by-line, read the original file
while {[gets $in line] != -1} {
    #transform $line somehow
    set line [string tolower $line]

    # then write the transformed line
    puts $out $line
}

close $in
close $out

# move the new data to the proper filename
file link -hard $filename $backup
file rename -force $temp $filename
5 голосов
/ 15 мая 2010

В дополнение к ответу Гленна. Если вы хотите работать с файлом на основе всего содержимого, а файл не слишком большой, вы можете использовать fileutil :: updateInPlace. Вот пример кода: 

package require fileutil

proc processContents {fileContents} {
    # Search: AA, replace: aa
    return [string map {AA aa} $fileContents]
}

fileutil::updateInPlace data.txt processContents
1 голос
/ 09 июня 2010

Если это Linux, было бы проще выполнить "sed -i" и позволить ему сделать всю работу за вас.

0 голосов
/ 14 июня 2010 
set fileID [open "lineremove.txt" r] 
set temp [open "temp.txt" w+] 
while {[eof $fileID] != 1} { 
    gets $fileID lineInfo 
    regsub -all "delted information type here" $lineInfo "" lineInfo 
    puts $temp $lineInfo 
} 
file delete -force lineremove.txt 
file rename -force temp.txt lineremove.txt
0 голосов
/ 11 июня 2010

Если это короткий файл, вы можете просто сохранить его в списке: 

set temp ""

#saves each line to an arg in a temp list
set file [open $loc]
foreach {i} [split [read $file] \n] {
    lappend temp $i
}
close $file

#rewrites your file
set file [open $loc w+]
foreach {i} $temp {
    #do something, for your example:
    puts $file [string tolower $i]
}
close $file
...