Как получить информацию и отсортировать подмножество элементов только с идентификаторами, использующими XSLT? - PullRequest
Новая
       20

Как получить информацию и отсортировать подмножество элементов только с идентификаторами, использующими XSLT?

2 голосов
/ 10 марта 2010

Я новичок в XSLT и не могу решить следующую проблему:

У меня есть XML-файл, подобный этому: 

<root>
    <subset>
        <e id="A"></e>
        <e id="C"></e>
    </subset>

    <data>
        <info id="A" order="3" name="ANode"></info>
        <info id="B" order="4" name="BNode"></info>
        <info id="C" order="1" name="CNode"></info>
        <info id="D" order="2" name="DNode"></info>
    </data>
</root>

И я хочу произвести это: 

<root>
    <newnode id="C" order="1" name="CNode"></newnode>
    <newnode id="A" order="3" name="ANode"></newnode>
</root>

Как видите, идея состоит в том, чтобы "завершить" подмножество идентификаторов путем извлечения соответствующей информации и отсортировать их в соответствии с порядком, указанным в <data>.

Обратите внимание, что <data> должен иметь много дочерних узлов.

Кроме того, я отделяю узлы с информацией об элементе <data> от подмножеств идентификаторов, потому что у меня будет много подмножеств, и я не хочу повторять информацию «везде».

Заранее спасибо.

Ответы [ 2 ]

2 голосов
/ 10 марта 2010

Перекрестные ссылки запрашивают использование ключей: 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output indent="yes"/>

  <xsl:key name="k1" match="info" use="@id"/>

  <xsl:template match="root">
    <xsl:copy>
      <xsl:apply-templates select="subset/e">
        <xsl:sort select="key('k1', @id)/@order" data-type="number"/>
      </xsl:apply-templates>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="e">
    <newnode id="{@id}" order="{key('k1', @id)/@order}" name="{key('k1', @id)/@name}"/>
  </xsl:template>

</xsl:stylesheet>

Это должно сделать для входного образца, который вы представили.

1 голос
/ 10 марта 2010

Вы также можете отключить подмножество в зависимости от того, что еще вам может понадобиться с вашими фактическими данными. 

<xsl:output indent="yes" />

<xsl:key name="subset" match="e" use="@id" />

<xsl:template match="/">
    <root>
    <xsl:for-each select="//info[count(key('subset',@id)[1]) &gt; 0]">
        <xsl:sort select="@order" data-type="number" />
        <newnode id="{@id}" order="{@order}" name="{@name}" />
    </xsl:for-each>
    </root>
</xsl:template>

...