Как кодировать Fizzbuzz в F #

Question

Я сейчас изучаю F # и попробовал (чрезвычайно) простой пример FizzBuzz.

Это моя первая попытка:

for x in 1..100 do 
    if x % 3 = 0 && x % 5 = 0 then printfn "FizzBuzz"  
    elif x % 3 = 0 then printfn "Fizz"
    elif x % 5 = 0 then printfn "Buzz"
    else printfn "%d" x

Какие решения могут быть более элегантными / простыми / лучше (объясняя почему), используя F # для решения этой проблемы?

Примечание. Задача FizzBuzz состоит из цифр от 1 до 100 и каждого из трех отпечатков Fizz, каждого из 5 отпечатков Buzz, каждого из трех и 5 отпечатков FizzBuzz. В противном случае просто отображается число.

Спасибо:)

Answer 1

Я думаю, что у вас уже есть "лучшее" решение.

Если вы хотите показать больше функциональных / F # -измов, вы можете сделать, например,

[1..100] 
|> Seq.map (function
    | x when x%5=0 && x%3=0 -> "FizzBuzz"
    | x when x%3=0 -> "Fizz"
    | x when x%5=0 -> "Buzz"
    | x -> string x)
|> Seq.iter (printfn "%s")

и используйте списки, последовательности, карту, iter, шаблоны и частичное применение.

[1..100]    // I am the list of numbers 1-100.  
            // F# has immutable singly-linked lists.
            // List literals use square brackets.

|>          // I am the pipeline operator.  
            // "x |> f" is just another way to write "f x".
            // It is a common idiom to "pipe" data through
            // a bunch of transformative functions.

   Seq.map  // "Seq" means "sequence", in F# such sequences
            // are just another name for IEnumerable<T>.
            // "map" is a function in the "Seq" module that
            // applies a function to every element of a 
            // sequence, returning a new sequence of results.

           (function    // The function keyword is one way to
                        // write a lambda, it means the same
                        // thing as "fun z -> match z with".
                        // "fun" starts a lambda.
                        // "match expr with" starts a pattern
                        // match, that then has |cases.

    | x when x%5=0 && x%3=0 
            // I'm a pattern.  The pattern is "x", which is 
            // just an identifier pattern that matches any
            // value and binds the name (x) to that value.
            // The "when" clause is a guard - the pattern
            // will only match if the guard predicate is true.

                            -> "FizzBuzz"
                // After each pattern is "-> expr" which is 
                // the thing evaluated if the pattern matches.
                // If this pattern matches, we return that 
                // string literal "FizzBuzz".

    | x when x%3=0 -> "Fizz"
            // Patterns are evaluated in order, just like
            // if...elif...elif...else, which is why we did 
            // the 'divisble-by-both' check first.

    | x when x%5=0 -> "Buzz"
    | x -> string x)
            // "string" is a function that converts its argument
            // to a string.  F# is statically-typed, so all the 
            // patterns have to evaluate to the same type, so the
            // return value of the map call can be e.g. an
            // IEnumerable<string> (aka seq<string>).

|>          // Another pipeline; pipe the prior sequence into...

   Seq.iter // iter applies a function to every element of a 
            // sequence, but the function should return "unit"
            // (like "void"), and iter itself returns unit.
            // Whereas sequences are lazy, "iter" will "force"
            // the sequence since it needs to apply the function
            // to each element only for its effects.

            (printfn "%s")
            // F# has type-safe printing; printfn "%s" expr
            // requires expr to have type string.  Usual kind of
            // %d for integers, etc.  Here we have partially 
            // applied printfn, it's a function still expecting 
            // the string, so this is a one-argument function 
            // that is appropriate to hand to iter.  Hurrah!

Answer 2

Мой пример - лишь небольшое улучшение по сравнению с кодом, опубликованным 'ssp'. Он использует параметризованные активные шаблоны (которые принимают в качестве аргумента делитель). Вот более подробное объяснение:

Следующее определяет активный шаблон , который мы можем позже использовать в match выражение для проверки, если значение i делится на значение divisor. Когда мы пишем:

match 9 with
| DivisibleBy 3 -> ...

... это означает, что значение '9' будет передано следующей функции как i, а значение 3 будет передано как divisor. Имя (|DivisibleBy|_|) - это специальный синтаксис, который означает, что мы объявляем активный шаблон (и имя может появиться в match на левой стороне ->. Бит |_| означает, что шаблон может потерпеть неудачу (наш пример завершается ошибкой, когда значение не делится на divisor)

let (|DivisibleBy|_|) divisor i = 

  // If the value is divisible, then we return 'Some()' which
  // represents that the active pattern succeeds - the '()' notation
  // means that we don't return any value from the pattern (if we
  // returned for example 'Some(i/divisor)' the use would be:
  //     match 6 with 
  //     | DivisibleBy 3 res -> .. (res would be asigned value 2)
  // None means that pattern failed and that the next clause should 
  // be tried (by the match expression)
  if i % divisor = 0 then Some () else None 

Теперь мы можем перебирать все числа и сопоставлять их с шаблонами (нашим активным шаблоном), используя match (или используя Seq.iter или другой метод, как показано в других ответах):

for i in 1..100 do
  match i with
  // & allows us to run more than one pattern on the argument 'i'
  // so this calls 'DivisibleBy 3 i' and 'DivisibleBy 5 i' and it
  // succeeds (and runs the body) only if both of them return 'Some()'
  | DivisibleBy 3 & DivisibleBy 5 -> printfn "FizzBuzz"
  | DivisibleBy 3 -> printfn "Fizz" 
  | DivisibleBy 5 -> printfn "Buzz" 
  | _ -> printfn "%d" i

Для получения дополнительной информации об активных шаблонах F #, вот ссылка на документацию MSDN . Я думаю, что если вы удалите все комментарии, код будет немного более читабельным, чем оригинальная версия. Он показывает некоторые довольно полезные трюки :-), но в вашем случае задача относительно проста ...

Answer 3

Еще одно решение в стиле F # (т.е. с использованием активных шаблонов):

let (|P3|_|) i = if i % 3 = 0 then Some i else None
let (|P5|_|) i = if i % 5 = 0 then Some i else None

let f = function
  | P3 _ & P5 _ -> printfn "FizzBuzz"
  | P3 _        -> printfn "Fizz"
  | P5 _        -> printfn "Buzz"
  | x           -> printfn "%d" x

Seq.iter f {1..100}
//or
for i in 1..100 do f i

Answer 4

Чтобы добавить еще один возможный ответ - вот еще один подход без сопоставления с образцом. Он использует тот факт, что Fizz + Buzz = FizzBuzz, поэтому вам не нужно проверять все три случая, нужно только посмотреть, делится ли оно на 3 (затем вывести «Fizz»), а также посмотреть, делится ли оно на 5 (затем выведите «Buzz») и, наконец, напечатайте новую строку:

for i in 1..100 do
  for divisor, str in [ (3, "Fizz"); (5; "Buzz") ] do
    if i % divisor = 0 then printf str
  printfn ""

Вложенный цикл for присваивает 3 и «Fizz» значения divisor и str в первой итерации, а затем вторую пару значений во второй итерации. Преимущество заключается в том, что вы можете легко добавить печать «Jezz», когда значение делится на 7 :-) ... в случае, если проблема заключается в расширяемости решения!

Answer 5

Я считаю, что это немного более читаемый ответ Отредактированный был вдохновлен другими

let FizzBuzz n =
    match n%3,n%5 with
    | 0,0 -> "FizzBuzz"
    | 0,_ -> "Fizz"
    | _,0 -> "Buzz"
    | _,_ -> string n

[1..100]
|> Seq.map (fun n -> FizzBuzz n)
|> Seq.iter (printfn "%s")

Answer 6

Вот еще один:

let fizzy num =     
   match num%3, num%5 with      
      | 0,0 -> "fizzbuzz"
      | 0,_ -> "fizz"
      | _,0 -> "buzz"
      | _,_ -> num.ToString()

[1..100]
  |> List.map fizzy
  |> List.iter (fun (s:string) -> printfn "%s" s)

Answer 7

Я не смог найти работающее решение, которое не включало бы тестирование для i% 15 = 0 . Я всегда чувствовал, что не тестирование для этого является частью этого "глупого" задания. Знайте, что это, вероятно, не идиоматический F #, так как это моя первая программа на языке.

for n in 1..100 do 
  let s = seq { 
    if n % 3 = 0 then yield "Fizz"
    if n % 5 = 0 then yield "Buzz" } 
  if Seq.isEmpty s then printf "%d"n
  printfn "%s"(s |> String.concat "")

Answer 8

Вот моя версия:

//initialize array a with values from 1 to 100
let a = Array.init 100 (fun x -> x + 1)

//iterate over array and match *indexes* x
Array.iter (fun x ->
    match x with
        | _ when x % 15 = 0 -> printfn "FizzBuzz"
        | _ when x % 5 = 0 -> printfn "Buzz"
        | _ when x % 3 = 0 -> printfn "Fizz"
        | _ -> printfn "%d" x
) a

Это моя первая программа на F #.

Это не идеально, но я думаю, что тот, кто начинает изучать F # (как я :)), может понять, что здесь происходит довольно быстро.

Однако мне интересно, в чем разница между сопоставлением с любым _ или x в сопоставлении с шаблоном выше?

Answer 9

Мне не нравятся все эти повторяющиеся строки, вот моя:

open System
let ar = [| "Fizz"; "Buzz"; |]
[1..100] |> List.map (fun i ->
    match i % 3 = 0, i % 5 = 0 with
        | true, false ->  ar.[0]
        | false, true ->  ar.[1] 
        | true, true ->  ar |> String.Concat
        | _ -> string i
    |> printf "%s\n"
)
|> ignore

Answer 10

Вот версия, подчеркивающая общий список кортежей:

let carbonations = [(3, "Spizz") ; (5, "Fuzz"); (15, "SpizzFuzz");
                    (30, "DIZZZZZZZZ"); (18, "WHIIIIII")]

let revCarbonated = carbonations |> List.sort |> List.rev

let carbonRoute someCarbonations findMe =
    match(List.tryFind (fun (x,_) -> findMe % x = 0) someCarbonations) with
        | Some x -> printfn "%d - %s" findMe (snd x)
        | None -> printfn "%d" findMe

let composeCarbonRoute = carbonRoute revCarbonated

[1..100] |> List.iter composeCarbonRoute