Добавление ссылки на кнопку во Flash / Actionscript

Question

Как сделать ссылку на кнопку, которая находится во фрагменте ролика Flash?

Answer 1

Предполагая, что у вашей кнопки есть имя экземпляра "myButton", в кадре, где находится ваша кнопка на временной шкале, вы добавите следующий (или аналогичный) ActionScript.

AS2

myButton.onPress = function()
{
   getURL("http://stackoverflow.com", "_blank");
}

AS3

import flash.events.MouseEvent;
import flash.net.navigateToURL;
import flash.net.URLRequest;
import flash.net.URLRequestMethod;

myButton.addEventListener(MouseEvent.CLICK, onMouseClick);
function onMouseClick(event:MouseEvent):void
{
   var request:URLRequest = new URLRequest("http://stackoverflow.com");
   request.method = URLRequestMethod.GET;
   var target:String = "_blank";
   navigateToURL(request, target);
}

Обратная совместимость getURL для AS3

/**
 * Backwards compatibility for global getURL function.
 *
 * @param url     Url to go to.
 * @param method  'get' or 'post'.
 * @param target  Window target frame [ex. '_blank'].
 */
public static function getURL(url:String, target:String = '_blank', method:String = 'get'):void
{
    method = method.toUpperCase();
    target = target.toLowerCase();

    if (method != URLRequestMethod.POST && method != URLRequestMethod.GET) method = URLRequestMethod.GET;
    if (target != "_self" && target != "_blank" && target != "_parent" && target != "_top") target = "_blank";
    var request:URLRequest = new URLRequest(url);
    request.method = method;
    navigateToURL(request, target);
}

Обратите внимание, что как в AS2, так и в AS3 вы можете написать этот код в классе и установить этот класс в качестве класса экспорта для вашей кнопки / мувиклипа. Это, вероятно, немного сложнее.