Замена SWI-пролога tokenize_atom / 2? - PullRequest
Новая
       17

Замена SWI-пролога tokenize_atom / 2?

1 голос
/ 27 марта 2010

Что мне нужно сделать, это разбить атом на токены. E. g.:

tokenize_string('Hello, World!', L).

объединит L=['Hello',',','World','!']. Точно так же, как и tokenize_atom/2. Но когда я пытаюсь использовать tokenize_atom/2 с нелатинскими буквами, это терпит неудачу. Есть ли универсальная замена или как можно ее написать? Заранее спасибо.

1 Ответ

3 голосов
/ 27 марта 2010

Ну, вы могли бы написать свой собственный лексер. Например, я могу показать вам лексер из моего анализатора арифметических выражений. 

:- use_module(library(http/dcg_basics)).

%
% lexer
%

lex([H | T]) -->
    lexem_t(H), !,
    lex(T).

lex([]) -->
    [].

lexem_t(L) --> trashes, lexem(L), trashes.

trashes --> trash, !, trashes.
trashes --> [].

trash --> comment_marker(End), !, string(_), End.
trash --> white.

comment_marker("*)") --> "(*".
comment_marker("*/") --> "/*".

hex_start --> "0X".
hex_start --> "0x".

lexem(open) --> "(".
lexem(close) --> ")".
lexem(+) --> "+".
lexem(-) --> "-".
lexem(*) --> "*".
lexem(/) --> "/".
lexem(^) --> "^".
lexem(,) --> ",".
lexem(!) --> "!".

lexem(N) --> hex_start, !, xinteger(N). % this handles hex numbers
lexem(N) --> number(N). % this handles integers/floats
lexem(var(A)) --> identifier_c(L), {string_to_atom(L, A)}.

identifier_c([H | T]) --> alpha(H), !, many_alnum(T).

alpha(H) --> [H], {code_type(H, alpha)}.
alnum(H) --> [H], {code_type(H, alnum)}.

many_alnum([H | T]) --> alnum(H), !, many_alnum(T).
many_alnum([]) --> [].

Как это работает: 

 ?- phrase(lex(L), "abc 123 привет 123.4e5 !+- 0xabc,,,"), write(L).
[var(abc), 123, var(привет), 1.234e+007, !, +, -, 2748, (,), (,), (,)]
...