Как симулировать битовые поля в записях Delphi?

Question

Я хотел бы объявить запись в Delphi, которая содержит тот же макет, что и в C.

Для заинтересованных: эта запись является частью объединения в записи LDT_ENTRY ОС Windows. (Мне нужно использовать эту запись в Delphi, потому что я работаю над эмулятором Xbox в Delphi - см. Проект Dxbx на sourceforge).

В любом случае, рассматриваемая запись определяется как:

    struct
    {
        DWORD   BaseMid : 8;
        DWORD   Type : 5;
        DWORD   Dpl : 2;
        DWORD   Pres : 1;
        DWORD   LimitHi : 4;
        DWORD   Sys : 1;
        DWORD   Reserved_0 : 1;
        DWORD   Default_Big : 1;
        DWORD   Granularity : 1;
        DWORD   BaseHi : 8;
    }
    Bits;

Насколько я знаю, в Delphi нет битовых полей. Я попробовал это:

 Bits = record
      BaseMid: Byte; // 8 bits
      _Type: 0..31; // 5 bits
      Dpl: 0..3; // 2 bits
      Pres: Boolean; // 1 bit
      LimitHi: 0..15; // 4 bits
      Sys: Boolean; // 1 bit
      Reserved_0: Boolean; // 1 bit
      Default_Big: Boolean; // 1 bit
      Granularity: Boolean; // 1 bit
      BaseHi: Byte; // 8 bits
  end;

Но увы: его размер становится 10 байтов вместо ожидаемых 4. Я хотел бы знать, как я должен объявить запись, чтобы я получил запись с тем же макетом, тем же размером и теми же участниками. Желательно без нагрузки геттеров / сеттеров.

ТИА.

Answer 1

Спасибо всем!

Основываясь на этой информации, я сократил ее до:

RBits = record
public
  BaseMid: BYTE;
private
  Flags: WORD;
  function GetBits(const aIndex: Integer): Integer;
  procedure SetBits(const aIndex: Integer; const aValue: Integer);
public
  BaseHi: BYTE;
  property _Type: Integer index $0005 read GetBits write SetBits; // 5 bits at offset 0
  property Dpl: Integer index $0502 read GetBits write SetBits; // 2 bits at offset 5
  property Pres: Integer index $0701 read GetBits write SetBits; // 1 bit at offset 7
  property LimitHi: Integer index $0804 read GetBits write SetBits; // 4 bits at offset 8
  property Sys: Integer index $0C01 read GetBits write SetBits; // 1 bit at offset 12
  property Reserved_0: Integer index $0D01 read GetBits write SetBits; // 1 bit at offset 13
  property Default_Big: Integer index $0E01 read GetBits write SetBits; // 1 bit at offset 14
  property Granularity: Integer index $0F01 read GetBits write SetBits; // 1 bit at offset 15
end;

Индекс кодируется следующим образом: (BitOffset shl 8) + NrBits. Где 1 <= NrBits <= 32 и 0 <= BitOffset <= 31 </p>

Теперь я могу получить и установить эти биты следующим образом:

{$OPTIMIZATION ON}
{$OVERFLOWCHECKS OFF}
function RBits.GetBits(const aIndex: Integer): Integer;
var
  Offset: Integer;
  NrBits: Integer;
  Mask: Integer;
begin
  NrBits := aIndex and $FF;
  Offset := aIndex shr 8;

  Mask := ((1 shl NrBits) - 1);

  Result := (Flags shr Offset) and Mask;
end;

procedure RBits.SetBits(const aIndex: Integer; const aValue: Integer);
var
  Offset: Integer;
  NrBits: Integer;
  Mask: Integer;
begin
  NrBits := aIndex and $FF;
  Offset := aIndex shr 8;

  Mask := ((1 shl NrBits) - 1);
  Assert(aValue <= Mask);

  Flags := (Flags and (not (Mask shl Offset))) or (aValue shl Offset);
end;

Довольно изящно, тебе не кажется?!?!

PS: Руди Велтуис теперь включил пересмотренную версию этого в свою превосходную статью «Подводные камни конвертации» .

Answer 2

Delphi Corner от Rudy - лучший из известных мне ресурсов о совместимости Delphi и C / C ++. Его Подводные камни конверсии в значительной степени должны быть прочитаны при использовании C / C ++ API в Delphi. Глава, которая вас больше всего заинтересует, это Записи и выравнивание -> Битовые поля , но я призываю вас прочитать всю вещь сверху вниз, дважды . Другие статьи, безусловно, тоже стоят затрат времени.

Answer 3

Хорошо, мои битовые манипуляции немного ржавые, поэтому я мог бы поменять местами байты Но код ниже дает общее представление:

type
  TBits = record
  private
    FBaseMid     : Byte;
    FTypeDplPres :  Byte;
    FLimitHiSysEa: Byte;
    FBaseHi      : Byte;

    function GetType: Byte;
    procedure SetType(const AType: Byte);
    function GetDpl: Byte;
    procedure SetDbl(const ADpl: Byte);
    function GetBit1(const AIndex: Integer): Boolean;
    procedure SetBit1(const AIndex: Integer; const AValue: Boolean);
    function GetLimitHi: Byte;
    procedure SetLimitHi(const AValue: Byte);
    function GetBit2(const AIndex: Integer): Boolean;
    procedure SetBit2(const AIndex: Integer; const AValue: Boolean);

  public
    property BaseMid: Byte read FBaseMid write FBaseMid;
    property &Type: Byte read GetType write SetType; // 0..31
    property Dpl: Byte read GetDpl write SetDbl; // 0..3
    property Pres: Boolean index 128 read GetBit1 write SetBit1; 
    property LimitHi: Byte read GetLimitHi write SetLimitHi; // 0..15

    property Sys: Boolean index 16 read GetBit2 write SetBit2; 
    property Reserved0: Boolean index 32 read GetBit2 write SetBit2; 
    property DefaultBig: Boolean index 64 read GetBit2 write SetBit2; 
    property Granularity: Boolean index 128 read GetBit2 write SetBit2; 
    property BaseHi: Byte read FBaseHi write FBaseHi;
  end;

  function TBits.GetType: Byte;
  begin
    Result := (FTypeDplPres shr 3) and $1F;
  end;

  procedure TBits.SetType(const AType: Byte);
  begin
    FTypeDplPres := (FTypeDplPres and $07) + ((AType and $1F) shr 3);
  end;

  function TBits.GetDpl: Byte;
  begin
    Result := (FTypeDplPres and $06) shr 1;
  end;

  procedure TBits.SetDbl(const ADpl: Byte);
  begin
    FTypeDblPres := (FTypeDblPres and $F9) + ((ADpl and $3) shl 1);
  end;

  function TBits.GetBit1(const AIndex: Integer): Boolean;
  begin
    Result := FTypeDplPres and AIndex = AIndex;
  end;

  procedure TBits.SetBit1(const AIndex: Integer; const AValue: Boolean);
  begin
    if AValue then
      FTypeDblPres := FTypeDblPres or AIndex
    else
      FTypeDblPres := FTypeDblPres and not AIndex;
  end;

  function TBits.GetLimitHi: Byte;
  begin
    Result := (FLimitHiSysEa shr 4) and $0F;
  end;

  procedure TBits.SetLimitHi(const AValue: Byte);
  begin
    FLimitHiSysEa := (FLimitHiSysEa and $0F) + ((AValue and $0F) shr 4);
  end;

  function TBits.GetBit2(const AIndex: Integer): Boolean;
  begin
    Result := FLimitHiSysEa and AIndex = AIndex;
  end;

  procedure TBits.SetBit2(const AIndex: Integer; const AValue: Boolean);
  begin
    if AValue then
      FLimitHiSysEa := FLimitHiSysEa or AIndex
    else
      FLimitHiSysEa := FLimitHiSysEa and not AIndex;
  end;

Answer 4

Ну, в основном вам нужно заняться грязью с помощью битовых манипуляций.

Почему, в частности, вам нужно сохранить эту структуру?

Если вам нужно только поговорить с устаревшей программой, которая либо говорит на этом диалекте (TCP / IP или аналогичный), либо хранит данные таким образом (файлы и т. Д.), То я бы сопоставил обычную структуру Delphi с бит-версия совместима. Другими словами, я бы использовал нормально структурированную структуру Delphi в памяти и написал бы код для написания и чтения этой структуры совместимым образом.

Если вам нужно сэкономить память, я бы сделал геттеры и сеттеры, которые манипулируют битами внутренних целых чисел или аналогичными. Это будет влиять на производительность, но не намного больше, чем исходная программа на C, единственное отличие состоит в том, что битовая манипуляция будет добавлена ​​магией компилятора в версии C, тогда как вам придется писать ее самостоятельно.

Если у вас мало записей в памяти и вам не нужно общаться с другой программой, я бы использовал естественную структуру Delphi. Компромисс для более высокой производительности будет больше памяти используется.

Но все зависит от ваших критериев.

В любом случае вы не сможете заставить компилятор Delphi выполнять ту же работу за вас, что и компилятор C.

УПАКОВАННАЯ ЗАПИСЬ, предложенная другим здесь, не делает этого и никогда не предназначалась. Он только удалит выравнивающие отступы, чтобы поставить целые числа на 32-разрядных границах и тому подобное, но не упаковывает несколько полей в один байт.

Обратите внимание, что распространенный способ сделать это - через Delphi SETS, которые реализуют внутренне, используя битовые поля. Опять же, у вас будет другой код, чем у варианта C.