Использование MBUnit в TeamCity

Question

Я собираю проект NAnt для Linux с сервером непрерывной интеграции TeamCity. Я смог сгенерировать отчет о тестировании, запустив NAnt на моно через Runner командной строки, но у меня нет возможности использовать отчет как NAnt Runner. Я также использую MBUnit для среды тестирования.

Как объединить отчет о тестировании и отобразить «Тесты не пройдены: 1 (1 новый), пройдено: 3049» для сборки?

Обновление: взгляните на MBUnitTask, это задача NAnt, которая использует отправку сообщений, ожидаемых TeamCity от NUnit, поэтому она позволяет использовать все функции TeamCity для тестов.

MBUnitTask

Обновление: В Galio улучшена поддержка, поэтому вам просто нужно ссылаться на DLL-библиотеки Galio MBUnit 3.5 вместо библиотек MBUnit 3.5 и переключиться на бегунок galio, чтобы он работал.

Answer 1

Теперь Gallio имеет расширение для вывода служебных сообщений TeamCity. Просто используйте включенный Gallio.NAntTasks.dll и включите расширение TeamCity. (в следующем выпуске не понадобится )

Answer 2

TeamCity наблюдает за выводом командной строки из сборки. Вы можете сообщить ему, как проходят ваши тесты, вставив определенные маркеры в этот вывод. См. http://www.jetbrains.net/confluence/display/TCD3/Build+Script+Interaction+with+TeamCity. Например,

##teamcity[testSuiteStarted name='Test1']

сообщит TeamCity о начале набора тестов. С MbUnit вы не можете выводить эти маркеры во время выполнения тестов, но вы можете преобразовать XML-файл, который он выводит. Вот XSL, который я использую:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:template match="/">

        <xsl:apply-templates/>

    </xsl:template>

    <xsl:template match="assemblies/assembly">
##teamcity[testSuiteStarted name='<xsl:value-of select="@name" />']

        <xsl:apply-templates select="//run" />

##teamcity[testSuiteFinished name='<xsl:value-of select="@name" />']
    </xsl:template>

    <xsl:template match="run">

        <xsl:choose>
            <xsl:when test="@result='ignore' or @result='skip'">
        ##teamcity[testIgnored name='<xsl:value-of select="@name" />' message='Test Ignored']
            </xsl:when>
            <xsl:otherwise>
        ##teamcity[testStarted name='<xsl:value-of select="@name" />']
            </xsl:otherwise>
        </xsl:choose>


        <xsl:if test="@result='failure'">
            ##teamcity[testFailed name='<xsl:value-of select="@name" />' message='<xsl:value-of select="child::node()/message"/>' details='<xsl:value-of select="normalize-space(child::node()/stack-trace)"/>']
        </xsl:if>


        <xsl:if test="@result!='ignore' and @result!='skip'">
        ##teamcity[testFinished name='<xsl:value-of select="@name" />']
        </xsl:if>

    </xsl:template>

</xsl:stylesheet>

Answer 3

Вот что я придумал

Как объединить протокол испытаний?

Сначала вам нужно получить mbunit для генерации отчета в формате XML и HTML. Аргументы командной строки выглядят так

/rt:Xml /rt:Html /rnf:mbunit /rf:..\reports

при этом отчеты будут сгенерированы в каталог, называемый отчетами, и файл будет называться mbunit.xml и mbunit.html

далее мы хотим добавить эти файлы в качестве артефактов при сборке

build\reports\* => Reports

последний шаг - указать teamcity добавить его в качестве вкладки для сборки

найдите .BuildServer \ config \ main-config.xml и добавьте эту строку (в Windows это находится в c: \ Documents and Settings \, в Linux это было в / root dir)

<report-tab title="Tests" basePath="Reports" startPage="mbunit.html" />

Как отобразить «Тесты не пройдены: 1 (1 новый), пройдено: 3049» для сборки?

TeamCity ищет файл с именем teamcity-info.xml, в который можно вставлять сообщения для отображения. Фактическое количество тестов на самом деле просто текст. Я думаю, вы можете просто добавить файл в качестве артефакта, но я также получил его в корневом каталоге сборки.

в NAnt вы хотите использовать эту команду для выполнения XSLT в отчете MBUnit XML

<style style="includes\teamcity-info.xsl" in="reports\mbunit.xml" out="..\teamcity-info.xml" />

фактический xsl выглядит следующим образом. (Примечание: что {и} зарезервированы в xsl, поэтому мы должны использовать params)

<?xml version="1.0" encoding="ISO-8859-1"?>

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="cbl" select="'{'"/>
<xsl:param name="cbr" select="'}'"/>
<xsl:template match="/">
<xsl:for-each select="report-result/counter">

<build number="1.0.{concat($cbl,'build.number',$cbr)}">
    <xsl:if test="@failure-count &gt; 0">
        <statusInfo status="FAILURE">    
            <text action="append"> Tests failed: <xsl:value-of select="@failure-count"/>, passed: <xsl:value-of select="@success-count"/></text>
        </statusInfo>
    </xsl:if>
    <xsl:if test="@failure-count = 0">
        <statusInfo status="SUCCESS">
            <text action="append"> Tests passed: <xsl:value-of select="@success-count"/></text>
        </statusInfo>
    </xsl:if>

</build>
</xsl:for-each>

</xsl:template>
</xsl:stylesheet>

Это даст вам файл, который выглядит так

<build number="1.0.{build.number}">
   <statusInfo status="FAILURE">
      <text action="append">Tests failed: 16, passed: 88</text>
   </statusInfo>
</build>

Answer 4

Гаджет для боковой панели TeamCity для Windows Vista, Windows 7 http://teamcity -gadget.com