Создайте функцию Oracle, которая возвращает таблицу - PullRequest
Новая
       18

Создайте функцию Oracle, которая возвращает таблицу

19 голосов
/ 13 мая 2010

Я пытаюсь создать функцию в пакете, которая возвращает таблицу. Я надеюсь вызвать функцию один раз в пакете, но смогу многократно использовать ее данные. Хотя я знаю, что я создаю временные таблицы в Oracle, я надеялся, что все останется СУХИМ.

Пока что вот что у меня есть:

Заголовок: 

CREATE OR REPLACE PACKAGE TEST AS 

    TYPE MEASURE_RECORD IS RECORD (
      L4_ID VARCHAR2(50),
      L6_ID VARCHAR2(50),
      L8_ID VARCHAR2(50),
      YEAR NUMBER,
      PERIOD NUMBER,
      VALUE NUMBER
    );

    TYPE MEASURE_TABLE IS TABLE OF MEASURE_RECORD;

    FUNCTION GET_UPS(
      TIMESPAN_IN IN VARCHAR2 DEFAULT 'MONTLHY',
      STARTING_DATE_IN DATE,
      ENDING_DATE_IN DATE  
    ) RETURN MEASURE_TABLE;

END TEST;

Body: 

CREATE OR REPLACE PACKAGE BODY TEST AS 

  FUNCTION GET_UPS (
    TIMESPAN_IN IN VARCHAR2 DEFAULT 'MONTLHY',
    STARTING_DATE_IN DATE,
    ENDING_DATE_IN DATE
  ) RETURN MEASURE_TABLE IS

    T MEASURE_TABLE;

  BEGIN

        SELECT  ...
        INTO    T
        FROM    ...

      ;

  RETURN T;

  END GET_UPS;

END TEST;

Заголовок компилируется, тело - нет. Одно сообщение об ошибке «недостаточно значений», что, вероятно, означает, что я должен выбирать в MEASURE_RECORD, а не в MEASURE_TABLE.

Чего мне не хватает?

Ответы [ 3 ]

32 голосов
/ 14 мая 2010

Я думаю, вы хотите конвейерную табличную функцию .

Примерно так: 

CREATE OR REPLACE PACKAGE test AS

    TYPE measure_record IS RECORD(
       l4_id VARCHAR2(50), 
       l6_id VARCHAR2(50), 
       l8_id VARCHAR2(50), 
       year NUMBER, 
       period NUMBER,
       VALUE NUMBER);

    TYPE measure_table IS TABLE OF measure_record;

    FUNCTION get_ups(foo NUMBER)
        RETURN measure_table
        PIPELINED;
END;

CREATE OR REPLACE PACKAGE BODY test AS

    FUNCTION get_ups(foo number)
        RETURN measure_table
        PIPELINED IS

        rec            measure_record;

    BEGIN
        SELECT 'foo', 'bar', 'baz', 2010, 5, 13
          INTO rec
          FROM DUAL;

        -- you would usually have a cursor and a loop here   
        PIPE ROW (rec);

        RETURN;
    END get_ups;
END;

Для простоты я удалил ваши параметры и не реализовал цикл в функции, но вы можете увидеть принцип.

Использование: 

SELECT *
  FROM table(test.get_ups(0));



L4_ID L6_ID L8_ID       YEAR     PERIOD      VALUE
----- ----- ----- ---------- ---------- ----------
foo   bar   baz         2010          5         13
1 row selected.
5 голосов
/ 14 мая 2010

Чтобы вернуть всю таблицу сразу, вы можете изменить SELECT на: 

SELECT  ...
BULK COLLECT INTO T
FROM    ...

Это рекомендуется только для результатов, которые не слишком велики, так как все они должны быть накоплены в памяти перед возвратом; в противном случае рассмотрим конвейерную функцию, предложенную Чарльзом, или возврат REF CURSOR.

0 голосов
/ 03 июля 2015 
  CREATE OR REPLACE PACKAGE BODY TEST AS 

   FUNCTION GET_UPS(
   TIMESPAN_IN IN VARCHAR2 DEFAULT 'MONTLHY',
   STARTING_DATE_IN DATE,
   ENDING_DATE_IN DATE
   )RETURN MEASURE_TABLE IS

    T MEASURE_TABLE;

 BEGIN

    **SELECT   MEASURE_RECORD(L4_ID , L6_ID ,L8_ID ,YEAR ,
             PERIOD,VALUE )  BULK COLLECT  INTO    T
    FROM    ...**

  ;

   RETURN T;

   END GET_UPS;

END TEST;
...