Выполнение динамического оператора SQL в SYS_REFCURSOR

Question

возможно ли выполнить динамический кусок sql внутри plsql и вернуть результаты в sys_refcursor? Я вставил свою попытку так далеко, но шов не работает, это ошибка, которую я получаю через мое Java-приложение

ORA-01006: переменная связывания не существует ORA-06512: в "LIVEFIS.ERC_REPORT_PK", строка 116 ORA-06512: в строке 1

но это может быть что-то неправильно истолковано Java, все швы для компиляции хорошо, так что я не уверен.

 procedure all_carers_param_dy (pPostcode in carer.postcode%type, pAge Number
                                ,pReport out SYS_REFCURSOR) is
  begin
    declare
      lsql  varchar2(500) :='SELECT c.id FROM carer c, cared_for cf,carer_cared_for ccf '
          ||' where c.id = ccf.carer_id (+)'
          ||' AND cf.id (+) = ccf.cared_for_id';

    begin

     if pPostcode is not null and pAge <= 0 then
        lsql := lsql||' AND c.postcode like ''%''|| upper(pPostcode)||''%''';
      elsif pPostcode is null and pAge > 0 then 
         lsql := lsql||' AND ROUND((MONTHS_BETWEEN(sysdate,c.date_of_birth)/12)) = pAge';
      elsif pPostcode is not null and pAge > 0 then
         lsql := lsql ||' AND ROUND((MONTHS_BETWEEN(sysdate,c.date_of_birth)/12)) = pAge'
                      ||' AND c.postcode like ''%''|| upper(pPostcode)||''%''';
      end if;


        execute immediate lsql
        into pReport;


    end;
  end;

Я новичок в plsql и еще новее в динамическом sql soo. Любая помощь / предложения будут высоко оценены.

Еще раз спасибо

Джон

Answer 1

вам придется связать параметры pAge и pPostcode. В динамическом SQL вы должны поставить их перед двоеточием (:). Если вы используете EXECUTE IMMEDIATE или OPEN ... FOR, вы будете связывать свои параметры с помощью позиции, поэтому я переименовал их: P1 и: P2 в примере:

DECLARE
   lsql VARCHAR2(500) := 'SELECT c.id 
                            FROM carer c, cared_for cf, carer_cared_for ccf 
                           WHERE c.id = ccf.carer_id (+)
                             AND cf.id (+) = ccf.cared_for_id';
BEGIN
   IF pPostcode IS NULL THEN
      lsql := lsql || ' AND :P1 IS NULL';
   ELSE
      lsql := lsql || ' AND c.postcode like ''%''|| upper(:P1)||''%''';
   IF pPostcode pAge > 0 THEN
      lsql := lsql || ' AND :P2 = ROUND((MONTHS_BETWEEN(sysdate,
                                                        c.date_of_birth)/12))';
   ELSE
      lsql := lsql || ' AND nvl(:P2, -1) <= 0';
   END IF;
   OPEN pReport FOR lsql USING pPostcode, pAge;
END;

Примечание: Число и положение переменных связывания должно быть известно во время компиляции , поэтому я часто использую приведенную выше конструкцию (добавляя параметр в его положение, даже если он не используется). Добавление тавтологии (как в AND :P1 IS NULL) к запросу не повлияет на его план объяснения.

Answer 2

Вы не можете назначить рефкурсор с помощью немедленного выполнения.

Вам нужно будет встроить SQL в строку, а затем использовать open.

sql_str := 'SELECT * FROM...';
open pReport for sql_str;

Answer 3

Используйте синтаксис OPEN FOR и переменные связывания.

procedure all_carers_param_dy (pPostcode in carer.postcode%type, pAge Number
                            ,pReport out SYS_REFCURSOR) 
is
  lsql  varchar2(500) :='SELECT c.id FROM carer c, cared_for cf,carer_cared_for ccf '
      ||' where c.id = ccf.carer_id (+)'
      ||' AND cf.id (+) = ccf.cared_for_id';

begin

 if pPostcode is not null and pAge <= 0 then
    lsql := lsql||' AND c.postcode like upper(''%''||:1||''%'')';
    open pReport for lsql using pPostcode;
  elsif pPostcode is null and pAge > 0 then 
     lsql := lsql||' AND ROUND((MONTHS_BETWEEN(sysdate,c.date_of_birth)/12)) = :1';
    open pReport for lsql using pAge;
  elsif pPostcode is not null and pAge > 0 then
     lsql := lsql ||' AND ROUND((MONTHS_BETWEEN(sysdate,c.date_of_birth)/12)) = :1'
                  ||' AND c.postcode like upper(''%''||:2||''%'')';
    open pReport for lsql using pAge, pPostcode;
  end if;

end all_carers_param_dy;
/

Динамический SQL сложен, труден для понимания и труден для понимания. Одна из хитрых областей - обработка повторений. Хорошей идеей будет объявлять повторяющиеся секции bolierplate как константы. Также обратите внимание, что мы можем разбить большие строки на несколько строк, не объединяя их с '||'. Это уменьшает накладные расходы на обслуживание.

create or replace procedure all_carers_param_dy 
    (pPostcode in carer.postcode%type
      , pAge Number 
      , pReport out SYS_REFCURSOR)  
is 
  lsql varchar2(500) ;

  root_string constant varchar2(500) :='SELECT c.id FROM carer c
                                , cared_for cf,carer_cared_for ccf   
                      where c.id = ccf.carer_id (+)  
                      and cf.id (+) = ccf.cared_for_id'; 
  pc_string constant varchar2(256) := 
      ' AND c.postcode like upper(''%''||:pc||''%'')';
  age_string constant varchar2(256) := 
      ' AND ROUND((MONTHS_BETWEEN(sysdate,c.date_of_birth)/12)) = :age';
begin 

 if pPostcode is not null and pAge <= 0 then 
    lsql := root_string || pc_string; 
    open pReport for lsql using pPostcode; 

  elsif pPostcode is null and pAge > 0 then  
     lsql := root_string || age_string; 
    open pReport for lsql using pAge; 

  elsif pPostcode is not null and pAge > 0 then 
     lsql := root_string || age_string 
                         || pc_string; 
    open pReport for lsql using pAge, pPostcode; 

  end if; 
end all_carers_param_dy; 
/