Как выполнить строковые операции с переменными в цикле for? - PullRequest
Новая
       9

Как выполнить строковые операции с переменными в цикле for?

8 голосов
/ 31 октября 2008

Звучит глупо, но я не могу заставить его работать. Я думаю, я просто не понимаю разницу между %%v, %v% and %v

Вот что я пытаюсь сделать: 

for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%v.jpg"

Это успешно генерирует миниатюру для каждого из фильмов, но проблема в следующем: 

movie.flv -> movie.flv.jpg

Итак, я хотел бы снять последние 4 символа с %%v и использовать это для второй переменной.

Я пробовал такие вещи: 

%%v:~0,-3%

Но это не работает, и ни одна из итераций того, о чем я мог подумать.

Есть идеи?

Ответы [ 5 ]

25 голосов
/ 10 июня 2011

Для людей, которые нашли этот поток, ищущий, как фактически выполнить строковые операции над переменными цикла (использует отложенное расширение ): 

setlocal enabledelayedexpansion

...

::Replace "12345" with "abcde"
for %%i in (*.txt) do (
    set temp=%%i
    echo !temp:12345=abcde!
)
9 голосов
/ 31 октября 2008 
for %%v in (*.flv) do ffmpeg.exe -i "%%v" -y -f mjpeg -ss 0.001 -vframes 1 -an "%%~nv.jpg"

Из "помощи для": 

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string
8 голосов
/ 31 октября 2008

Используйте %% ~ nV, чтобы получить только имя файла.

2 голосов
/ 31 октября 2008

Я не так хорош в пакетном режиме, как указано выше (вместо этого я использую WSH или другие языки сценариев), но могу попытаться объяснить %% v% v и% v%.

Первые две формы используются в цикле for. help for объясняет разницу: первая форма используется в командном файле, а вторая - при вводе (вставке) команды непосредственно в командной строке.

Последняя форма просто заменяет имя переменной (переменной среды) на ее значение: 

set FOO=C:\bar\foo
cd %FOO%\gah
0 голосов
/ 29 апреля 2016

Еще один способ, который я предпочитаю, - это создать подпрограмму (: processMpeg), которую я вызываю для каждого элемента в цикле For, которому я передаю переменную %% v. 

for %%v in (*.flv) do call :processMpeg "%%v"
goto :eof

:processMpeg
  set fileName=%~n1
  echo P1=%1  fileName=%fileName%  fullpath=%~dpnx1
  ffmpeg.exe -i "%~1" -y -f mjpeg -ss 0.001 -vframes 1 -an "%filename%.jpg"
  goto :eof
...