Как получить имя переменной, входящей в функцию в качестве параметра, используя F #?

Question

Есть ли способ в F #, как получить имя переменной, переданной в функцию?

Пример:

let velocity = 5
let fn v = v.ParentName
let name = fn velocity // this would return "velocity" as a string

Заранее спасибо

EDIT:

Почему этот код не работает? Это соответствует как значение, поэтому я не могу получить имя «переменной».

type Test() =
  let getName (e:Quotations.Expr) =
    match e with
      | Quotations.Patterns.PropertyGet (_, pi, _) -> pi.Name + " property"
      | Quotations.Patterns.Value(a) -> failwith "Value matched"
      | _ -> failwith "other matched"
  member x.plot v = v |> getName |> printfn "%s"

let o = new Test()

let display () =
  let variable = 5.
  o.plot <@ variable @>

let runTheCode fn = fn()

runTheCode display

Answer 1

Для завершения ответа Марсело, да, вы можете использовать цитаты для этой задачи:

open Microsoft.FSharp.Quotations
open Microsoft.FSharp.Quotations.Patterns

let velocity = 5

let fn (e:Expr) =
  match e with
    | PropertyGet (e, pi, li) -> pi.Name
    | _ -> failwith "not a let-bound value"

let name = fn <@velocity@> 

printfn "%s" name

Как видно из кода, значения верхнего определения (функции или переменные) с привязкой к F # реализованы как свойства класса.

Я больше не могу найти ссылку, которая показывает, как часть кода F # может быть функционально переписана с помощью C #. При просмотре кода становится очевидно, зачем вам нужен шаблон PropertyGet.

Теперь, если вы также хотите оценить выражение, вам нужно будет установить F # powerpack и ссылку FSharp.PowerPack.Linq в вашем проекте.

Он добавляет EvalUntyped метод к классу Expr.

open Microsoft.FSharp.Linq.QuotationEvaluation

let velocity = 5

let fn (e:Expr) =
  match e with
    | PropertyGet (eo, pi, li) -> pi.Name, e.EvalUntyped
    | _ -> failwith "not a let-bound value"

let name, value = fn <@velocity@> 

printfn "%s %A" name value

Если вам нужно сделать это для метода экземпляра, вот как я бы это сделал:

let velocity = 5

type Foo () =
  member this.Bar (x:int) (y:single) = x * x + int y

let extractCallExprBody expr =
  let rec aux (l, uexpr) =
    match uexpr with
     | Lambda (var, body) -> aux (var::l, body)
     | _ -> uexpr
  aux ([], expr)

let rec fn (e:Expr) =
  match e with
    | PropertyGet (e, pi, li) -> pi.Name
    | Call (e, mi, li) -> mi.Name
    | x -> extractCallExprBody x |> fn
    | _ -> failwith "not a valid pattern"

let name = fn <@velocity@> 
printfn "%s" name

let foo = new Foo()

let methodName = fn <@foo.Bar@>
printfn "%s" methodName

Просто чтобы вернуться к фрагменту кода, показывающему использование EvalUntyped, вы можете добавить явный параметр типа для Expr и downcast (:?>), если вы хотите / должны поддерживать безопасность типов:

let fn (e:Expr<´T>) = //using ´ instead of ' to avoid colorization screw-up
  match e with
    | PropertyGet (eo, pi, li) -> pi.Name, (e.EvalUntyped() :?> ´T)
    | _ -> failwith "not a let-bound value"

let name, value = fn <@velocity@> //value has type int here
printfn "%s %d" name value

Answer 2

Вы можете достичь этого с помощью цитат из кода:

let name = fn <@ velocity @>

Функция fn будет передана объекту Expr, который она должна привести к Quotations.Var (что будет, только если вы передадите одну переменную) и извлечь элемент экземпляра Name.

Answer 3

Основываясь на предыдущих решениях, я предложил более общее решение, в котором вы можете получить имена функций, лямбда-выражения, значения, свойства, методы, статические методы, открытые поля, типы объединения:

open Microsoft.FSharp.Quotations
open Microsoft.FSharp.Quotations.Patterns

let cout (s:string)= System.Console.WriteLine (s)

let rec getName exprs =
    let fixDeclaringType (dt:string) =
        match dt with
        | fsi  when fsi.StartsWith("FSI_") -> "Fsi"
        | _ -> dt
    let toStr (xDeclType: System.Type) x = sprintf "%s.%s" (fixDeclaringType xDeclType.Name)  x
    match exprs with
    | Patterns.Call(_, mi, _) -> 
        toStr mi.DeclaringType mi.Name
    | Patterns.Lambda(_, expr) -> 
        getName expr
    | Patterns.PropertyGet (e, pi, li) ->  
        toStr pi.DeclaringType pi.Name
    | Patterns.FieldGet (_, fi) -> 
        toStr fi.DeclaringType fi.Name
    | Patterns.NewUnionCase(uci, _) -> 
        toStr uci.DeclaringType uci.Name
    | expresion -> "unknown_name"


let value = ""
let funcky a = a
let lambdy = fun(x) -> x*2
type WithStatic = 
    | A | B
    with static member StaticMethod a = a
let someIP = System.Net.IPAddress.Parse("10.132.0.48")


getName <@ value @> |> cout
getName <@ funcky @> |> cout
getName <@ lambdy @> |> cout
getName <@ WithStatic.A @> |> cout
getName <@ WithStatic.StaticMethod @> |> cout
getName <@ someIP.MapToIPv4 @> |> cout  
getName <@ System.Net.IPAddress.Parse @> |> cout  
getName <@ System.Net.IPAddress.Broadcast @> |> cout