XSLT генерирует атрибуты, если source-Element находится в файле параметров

Question

я получил xml-файл с некоторыми элементами. Для некоторых из них есть эквивалент в xml-файле параметров вместе с некоторыми другими элементами. Я хочу добавить эти другие элементы из parm-файла в качестве параметра в выходной файл, если имена элементов совпадают. (Атрибуты должны генерироваться только в том случае, если в source-xml существует элемент «InvoiceHeader».

Вот мой код ...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions">  
    <xsl:variable name="rpl" select="document('ParamInvoice.xml')"></xsl:variable>
       <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
       <xsl:template match="/">
             <xsl:apply-templates></xsl:apply-templates>
       </xsl:template>
       <xsl:template match="*">
          <xsl:copy>
          <xsl:if test="$rpl/StoraInvoice/local-name()">
            <xsl:call-template name="AttributeErzeugen">
               <xsl:with-param name="attr" select="$rpl/StoraInvoice/local-name()"></xsl:with-param>
      </xsl:call-template>
     </xsl:if>
    <xsl:apply-templates></xsl:apply-templates>
 </xsl:copy>
</xsl:template>
     <xsl:template name="AttributeErzeugen">
        <xsl:param name="attr"></xsl:param>
            <xsl:for-each select="$attr">
              <xsl:attribute name="{Attibute/@name}"><xsl:value-of select="."></xsl:value-  of></xsl:attribute>  
         </xsl:for-each>
      </xsl:template>
    </xsl:stylesheet>

а вот парам-файл

<?xml version="1.0" encoding="UTF-8"?>
<StoraInvoice>
   <InvoiceHeader>
      <Attribute name="Fuehrend">YYY</Attribute>
      <Attribute name="Feld">FFFF</Attribute>
      <Attribute name="Format">XYZXYZ</Attribute>
   </InvoiceHeader>
</StoraInvoice>

Зигфрид

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my"
 exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <my:rpl>
  <StoraInvoice>
   <t>
     <InvoiceHeader>
      <Attribute name="Fuehrend">YYY</Attribute>
      <Attribute name="Feld">FFFF</Attribute>
      <Attribute name="Format">XYZXYZ</Attribute>
     </InvoiceHeader>
   </t>
  </StoraInvoice>
 </my:rpl>


 <xsl:variable name="rpl" select="document('')/*/my:rpl"/>

 <xsl:template match="*">
   <xsl:variable name="vInvoiceElement" select=
       "$rpl/StoraInvoice/*[name()=name(current())]"/>

   <xsl:copy>
     <xsl:if test="$vInvoiceElement">
        <xsl:call-template name="AttributeErzeugen">
          <xsl:with-param name="pInvoiced" select="$vInvoiceElement"/>
        </xsl:call-template>
     </xsl:if>
     <xsl:apply-templates/>
   </xsl:copy>
 </xsl:template>

 <xsl:template name="AttributeErzeugen">
  <xsl:param name="pInvoiced"/>
  <xsl:for-each select="$pInvoiced/InvoiceHeader/Attribute">
    <xsl:attribute name="{@name}">
     <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML:

<t/>

дает желаемый, правильный результат :

<t Fuehrend="YYY" Feld="FFFF" Format="XYZXYZ"/>