Как изящно выйти из SLIME и Emacs? - PullRequest
Новая
       35

Как изящно выйти из SLIME и Emacs?

13 голосов
/ 25 февраля 2010

У меня есть вопрос о том, как "изящно выйти из SLIME", когда я выйду из Emacs. Вот соответствующая часть моего файла конфигурации: 

;; SLIME configuration

(setq inferior-lisp-program "/usr/local/bin/sbcl")
(add-to-list 'load-path "~/Scripts/slime/")
(require 'slime)
(slime-setup)

;; configure SLIME to gracefully quit when emacs
;; terminates

(defun slime-smart-quit ()
  (interactive)
  (when (slime-connected-p)
    (if (equal (slime-machine-instance) "Gregory-Gelfonds-MacBook-Pro.local")
 (slime-quit-lisp)
      (slime-disconnect)))
  (slime-kill-all-buffers))

(add-hook 'kill-emacs-hook 'slime-smart-quit)

Насколько мне известно, это должно автоматически убивать SLIME и связанные с ним процессы всякий раз, когда я выхожу из Emacs. Тем не менее, каждый раз, когда я выхожу, я все равно получаю приглашение: 

Proc       Status   Buffer  Command
----       ------   ------  -------
SLIME Lisp    open      *cl-connection* (network stream connection to 127.0.0.1)
inferior-lisp run      *inferior-lisp* /usr/local/bin/sbcl


Active processes exist; kill them and exit anyway? (yes or no)

Может ли кто-нибудь пролить свет на то, что мне не хватает в моей конфигурации?

Заранее спасибо.

Ответы [ 8 ]

23 голосов
/ 04 августа 2010

Я знаю, что это не совсем то, что вы просили, но, возможно, это будет полезно для других нубов, таких как я.

Вы можете выполнить команду SLIME , чтобы выйти, и у вас останется хороший, чистый Emacs.

В буфере SLIME введите , (запятая). Вы помещены в минибуфер, и SLIME спрашивает, какую команду выполнить. Введите sayoonara и нажмите Введите . Вы должны увидеть выход SLIME, минибуфер упоминает, что «Соединение закрыто». и вы помещены в буфер * scratch *.

Интересно, есть ли способ просто вызвать эту команду "sayoonara" из вашего .emacs, в отличие от ручного отключения всего.

4 голосов
/ 16 ноября 2010

Согласно странице руководства на этом , "как только save-buffers-kill-emacs завершает сохранение и подтверждение всех файлов, он вызывает kill-emacs, который выполняет функции в этой ловушке". Поэтому проверка активных процессов выполняется до вызова ловушки.

Рабочим решением было бы создать собственную команду kill-emacs, например 

(defun kill-emacs-slime ()
  (interactive)
  (when (slime-connected-p)
    (if (equal (slime-machine-instance) "Gregory-Gelfonds-MacBook-Pro.local")
        (slime-quit-lisp)
      (slime-disconnect)))
  (slime-kill-all-buffers)
  (save-buffers-kill-emacs))

А затем свяжите это с вашим ключом выхода 

(global-set-key (kbd "C-x C-c") 'kill-emacs-slime)

(Я предполагаю, что ваша функция правильно вышла из SLIME и закрыла его буферы, я не проверял это).

3 голосов
/ 16 ноября 2010

Проблема в том, что проверка на активные процессы (и запрос подтверждения на удаление) будет активирована до того, как kill-emacs-hooks сможет выполнить свою работу.

Очень грязное решение: 

(defadvice save-buffers-kill-terminal (before slime-quit activate)
  (slime-smart-quit)
  (sleep-for 1))

Функция slime-quit-lisp является асинхронной; после возвращения нужно время, поэтому sleep-for.

2 голосов
/ 07 декабря 2010

@ Алекс - Я нашел твой метод самым чистым способом выйти из SLIME. Однако файл конфигурации необходимо отредактировать таким образом, чтобы использовать его. 

(require 'slime-autoloads)
(slime-setup '(slime-fancy)) ; load contrib packages

Как только он настроен таким образом, тогда:

  1. нажмите запятую (,) , чтобы вызвать минибуфер
  2. введите выйти или sayoonara , чтобы чисто выйти.

PS: проверьте это для конфигурации SLIME при запуске - http://common -lisp.net / project / slime / doc / html / Loading-Contribs.html

2 голосов
/ 26 февраля 2010

Одним из способов устранения проблемы является отладка функции.

Поместите курсор в подпрограмму 'slime-smart-quit и введите M-x edebug-defun . Затем выйдите из Emacs, как обычно. Затем вам будет предложен отладчик lisp Emacs edebug . Это довольно простой в использовании отладчик (введите ? для справки).

Пройдите по коду и посмотрите, где он не работает, как вы ожидаете.

Используйте q , чтобы выйти из отладчика, затем внесите изменения, и M-x edebug-defun снова, чтобы отладить новую версию.

Повторяйте до тех пор, пока не найдете успех, или у вас будет немного больше информации для вопроса.

1 голос
/ 19 апреля 2012

Меня раздражает необходимость соглашаться убивать все процессы каждый раз, когда я закрываю Emacs, поэтому я придумываю эту функцию 

(defun emacs-forget-buffer-process ()
  "Emacs will not query about this process when killing."
  (let ((p (get-buffer-process (current-buffer))))
    (when p
      (set-process-query-on-exit-flag p nil))))

, что заставляет процесс молча умирать, когда Emacs закрыт. Используйте это так 

(add-hook 'slime-inferior-process-start-hook #'emacs-forget-buffer-process)
(add-hook 'slime-repl-mode-hook #'emacs-forget-buffer-process)

Я использую его для всех моих репликоподобных буферов, которые включают октаву, питон, схему, оболочку и ghci для haskell. Пока ничего плохого не случилось, когда эти реплеры были убиты молча, поэтому я полагаю, что это решение не плохое, хотя и не изящное.

0 голосов
/ 01 июня 2012

Нет, нет, нет. https://stackoverflow.com/a/10780124/539797; любой другой способ уничтожения буфера процесса в лучшем случае груб, если не опасен для детей и щенков.

0 голосов
/ 04 мая 2012

Это более общее решение, которое я использую. Это работает не только для SLIME, но и для других вещей, например питон, терминал, лисп и т. д. 

(defadvice save-buffers-kill-emacs (around no-query-kill-emacs activate)
  "Prevent annoying \"Active processes exist\" query when you quit Emacs."
  (flet ((process-list ())) ad-do-it))
...