Как я могу получить значение из пары ключ / значение xml с xpath в моем xslt?

Question

У меня есть xml, который я хочу обработать, используя xslt. Значительное количество данных поступает в виде пар ключ-значение (см. Ниже). Я борюсь с тем, как извлечь базу значений ключа в переменную. Я хотел бы иметь возможность сделать что-то вроде этого:

<xsl:variable name="foo" select="/root/entry[key = 'foo']/value"/>

но это не похоже на работу. Вот пример xml.

<?xml version="1.0" encoding="ISO-8859-1"?>
<root>
  <entry>
    <key>
      foo
    </key>
    <value>
      bar
    </value>
  </entry>
</root>

Каким будет правильный xpath для этого?

Answer 1

Следующее преобразование показывает два способа достижения этого - с использованием и без использования <xsl:key> и функции key():

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes"/>

 <xsl:key name="kValueByKey"
   match="value" use="normalize-space(../key)"/>

 <xsl:template match="/">
   1. By key: <xsl:text/>

   <xsl:copy-of select="key('kValueByKey', 'foo')"/>

   2. Not using key:  <xsl:text/>

   <xsl:copy-of select="/*/*[normalize-space(key)='foo']/value"/>
 </xsl:template>
</xsl:stylesheet>

Примечаниеиспользование функции normalize-space() для удаления любых начальных или конечных пробельных символов из значения <key>.

Answer 2

Ваш XPath отлично работает для следующего (эквивалентного) документа:

<?xml version="1.0" encoding="ISO-8859-1"?>
<root>
 <entry>
  <key>foo</key>
  <value>
   bar
  </value>
 </entry>
</root>

Вы можете использовать функцию xpath contains, чтобы получить тот же результат без изменения структуры XML:

<xsl:variable name="foo" select="/root/entry[contains(key,'foo')]/value"/>

Answer 3

<xsl:variable name="foo" select="/root/entry[key='foo']/value" />

Это точное совпадение, поэтому убедитесь, что в вашем XML нет лишних пробелов или символов новой строки вокруг foo . В противном случае используйте функцию замены и регулярное выражение для их обрезки.