Управление генерацией символов в макросах Clojure - PullRequest
Новая
       38

Управление генерацией символов в макросах Clojure

19 голосов
/ 15 мая 2010

Я пытаюсь (как упражнение для самообучения) создать макрос Clojure, который будет генерировать код для применения функции к последовательности целых чисел и суммирования результата, например,

f (0) + f (1) + f (2) + f (3)

Это моя попытка: 

(defmacro testsum [func n] 
  `(fn [x#] (+ ~@( map (fn [i] `(~func x#)) (range n)))))

Однако с x # gensym что-то не так, и я получаю две разные версии x, и, следовательно, функция не работает: 

(macroexpand '(testsum inc 3))

дает: 

(fn* ([x__809__auto__] 
  (clojure.core/+ 
    (inc x__808__auto__) 
    (inc x__808__auto__) 
    (inc x__808__auto__))))

Это в значительной степени именно то, что я хочу, кроме разных версий 809 и 808 х .....

Что я делаю не так? Я думал, что автогенсим должен был создать единый уникальный символ именно для этой цели? Есть ли лучший способ сделать это?

1 Ответ

24 голосов
/ 15 мая 2010
Генсимы в стиле

foo# действительны только внутри синтаксической кавычки, в которой они были созданы. В вашем коде два x# создаются в разных блоках синтаксических кавычек: 

(defmacro testsum [func n] 
  `(fn [x#] (+ ~@( map (fn [i] `(~func x#)) (range n)))))
  ^- s-q1      ^-unquote       ^- s-q2

Чтобы исправить это, используйте явный (gensym) вызов: 

(defmacro testsum [func n]
  (let [x (gensym "x")]
    `(fn [~x] (+ ~@(map (fn [i] `(~func ~x)) (range n))))))

И расширение макроса ((macroexpand '(testsum inc 3))): 

(fn* ([x4966] (clojure.core/+ (inc x4966) (inc x4966) (inc x4966))))
...