Как я могу преобразовать строку типа 3 10 ^ -20 в число в Perl?

Question

У меня есть файл, который содержит список чисел, который выглядит следующим образом:

10^-92
2 10^-14
10^-105
3 10^-20

Для пояснения немного 10^-92 - это, по сути, 1E-92, а 2 10^-14 - это 2E^-14. Есть ли компактный способ преобразовать число в файле выше в число Perl? В конце я хочу отсортировать эти числа численно.

Answer 1

Если для преобразования чисел в Perl все ваши числа требуют одинакового преобразования, почему бы не использовать подстановку регулярных выражений:

use 5.010;

my @nums = ('10^-92', '2 10^-14', '10^-105', '3 10^-20');

s{ (\d*) \s* 10\^ }{ ($1 || 1) . 'e' }xe for @nums;

say "@nums";  # 1e-92 2e-14 1e-105 3e-20

Answer 2

Если вам нужен номер Perl, просто перейдите прямо к номеру без пробела. Сохраните части номера, которые вы извлекаете, и используйте их в сортировке с ключом:

use 5.010;

while( <DATA> )
    {
    chomp;

    m/
        (?:
            (?<coefficient> \d+ (?:\.\d+)? )
            \s+
        )?

        (?<base> (\d+) )

        \^

        (?<exponent> -?\d+ )
    /x;


    push @numbers,
        [ ( $+{coefficient} // 1 ), $+{exponent}, $_ ];
    }

my @sorted = sort {
    $a->[1] <=> $b->[1]
        ||
    $a->[0] <=> $b->[0]
    } @numbers;

foreach my $number ( @sorted )
    {
    print "$number->[-1]\n";
    }

__DATA__
10^-92
2 10^-14
10^-105
3 10^-20

Вы можете свести это к преобразованию Шварца:

use 5.010;

print
map {
    $_->[-1]
    }
sort {
    $a->[1] <=> $b->[1]
        ||
    $a->[0] <=> $b->[0]
    }
map {
    m/
        (?:(?<c> \d+ (?:\.\d+)? ) \s+ )? # coefficient
        (?<b> (\d+) )                    # base
        \^
        (?<e> -?\d+ )                    # exponent
    /x;
    [ ( $+{c} // 1 ), $+{e}, $_ ];
    } <DATA>;


__DATA__
10^-92
2 10^-14
10^-105
3 10^-20

Answer 3

$ perl -ne 's/ /*/;s/\^/E/;print "\n".eval $_' file

2e-13
1e-91
2e-13
1e-104
3e-19