Как назначить результат exec переменной sql?

Question

Как назначить результат вызова exec переменной в SQL? У меня есть сохраненный процесс с именем up_GetBusinessDay, который возвращает одну дату.

Можете ли вы сделать что-то вроде этого:

exec @PreviousBusinessDay = dbo.up_GetBusinessDay @Date, -1

Answer 1

Я всегда использую возвращаемое значение для возврата статуса ошибки. Если вам нужно вернуть одно значение, я бы использовал выходной параметр.

образец хранимой процедуры с параметром OUTPUT:

CREATE PROCEDURE YourStoredProcedure 
(
    @Param1    int
   ,@Param2    varchar(5)
   ,@Param3    datetime OUTPUT
)
AS
IF ISNULL(@Param1,0)>5
BEGIN
    SET @Param3=GETDATE()
END
ELSE
BEGIN
    SET @Param3='1/1/2010'
END
RETURN 0
GO

вызов хранимой процедуры с параметром OUTPUT:

DECLARE @OutputParameter  datetime
       ,@ReturnValue      int

EXEC @ReturnValue=YourStoredProcedure 1,null, @OutputParameter OUTPUT
PRINT @ReturnValue
PRINT CONVERT(char(23),@OutputParameter ,121)

ВЫВОД:

0
2010-01-01 00:00:00.000

Answer 2

Это будет работать, если вы хотите просто вернуть целое число:

DECLARE @ResultForPos INT 
EXEC @ResultForPos = storedprocedureName 'InputParameter'
SELECT @ResultForPos

Answer 3

declare @EventId int

CREATE TABLE #EventId (EventId int)

insert into #EventId exec rptInputEventId

set @EventId = (select * from #EventId)

drop table #EventId 

Answer 4

Из документации (при условии, что вы используете SQL-сервер):

USE AdventureWorks;
GO
DECLARE @returnstatus nvarchar(15);
SET @returnstatus = NULL;
EXEC @returnstatus = dbo.ufnGetSalesOrderStatusText @Status = 2;
PRINT @returnstatus;
GO

Так что да, так и должно быть.