Groovy + Antbuilder: Как использовать Grape для работы с taskdef? - PullRequest
Новая
       49

Groovy + Antbuilder: Как использовать Grape для работы с taskdef?

4 голосов
/ 27 февраля 2010

Это связано с. Я пытаюсь динамически добавить банки maven-ant-tasks с Grape, имитируя это: 

  <taskdef uri="antlib:org.apache.maven.artifact.ant"
           resource="org/apache/maven/artifact/ant/antlib.xml"
           classpathref="ant.classpath" />

Я пытался использовать Grape.grab (), чтобы сделать задачи maven-ant доступными для AntBuilder, например: 

import groovy.grape.Grape

println "grab..."
Grape.grab(group:'ant', module:'ant', version:'1.7.0', classLoader:this.class.classLoader.rootLoader)
Grape.grab(group: 'org.apache.maven', module: 'maven-ant-tasks', version: '2.0.9')

println "ant taskdef..."
def ant = new AntBuilder()
ant.taskdef (resource: "org/apache/maven/artifact/ant/antlib.xml" )

но это не работает, потому что Grape добавляет модули в другой ClassLoader из того, который использует движок ANT. Итак, я взял совет от этого вопроса о пути к классам AntBuilder и заставил Grape использовать rootLoader: 

import groovy.grape.Grape

println "grab..."
Grape.grab(group:'ant', module:'ant', version:'1.7.0', classLoader:this.class.classLoader.rootLoader)
Grape.grab(group: 'org.apache.maven', module: 'maven-ant-tasks', version: '2.0.9', classLoader: this.class.classLoader.rootLoader)

println "ant taskdef..."
def ant = new AntBuilder()
ant.taskdef (resource: "org/apache/maven/artifact/ant/antlib.xml" )

Теперь выдает ошибку LinkageError: 

Caught: : java.lang.LinkageError: loader constraint violation: when resolving overridden method "org.apache.tools.ant.helper.ProjectHelper2$RootHandler.setDocumentLocator(Lorg/xml/sax/Locator;)V" the class loader (instance of org/codehaus/groovy/tools/RootLoader) of the current class, org/apache/tools/ant/helper/ProjectHelper2$RootHandler, and its superclass loader (instance of <bootloader>), have different Class objects for the type org/xml/sax/Locator used in the signature
 at test.mavenanttasks.run(mavenanttasks.groovy:11)

Любые намеки на то, чтобы заставить это работать? Или все это плохая идея?

Ответы [ 2 ]

2 голосов
/ 18 июля 2015

Мы можем создать ant path (classpath), используя java.net.URLClassLoader или его подкласс например: 

<!-- language: groovy -->
@Grapes([
    @Grab(group='org.jacoco', module='org.jacoco.ant', version= '0.7.4.201502262128'),
    @Grab(group='org.jacoco', module='org.jacoco.core', version= '0.7.4.201502262128'),
    @Grab('org.jacoco:org.jacoco.report:0.7.4.201502262128'),   
])
class Tool {
    def dump(args){
        println "do dump...:$args"
        println "DumpTask:"+org.jacoco.ant.DumpTask.classLoader;
        def ant = new AntBuilder();
        def path1 = ant.path{
            org.jacoco.ant.DumpTask.classLoader.getURLs().each {
                ant.pathelement(location:it.getFile())
            }
        } 
        println "path11:$path1";

    // classname way
    //  ant.taskdef(name:"dump",classname:"org.jacoco.ant.DumpTask",classpath:path1);
    //  ant.dump(args);

        //namespace way
        ant.taskdef(uri:'antlib:org.jacoco.ant',resource:'org/jacoco/ant/antlib.xml',classpath:path1);
        def jacoco=groovy.xml.NamespaceBuilder.newInstance(ant, 'antlib:org.jacoco.ant')
        jacoco.dump(args);
    }
}
2 голосов
/ 24 июня 2010

Я нашел это: http://groovy.codehaus.org/Using+Ant+Libraries+with+AntBuilder

Сначала поместите maven-ant-tasks в корневой загрузчик классов с помощью: 

@Grapes([
@Grab(group = 'org.apache.maven', module = 'maven-ant-tasks', version = '2.1.3'),
@GrabConfig(systemClassLoader = true)
])

В качестве альтернативы для более старых версий Groovy: 

Grape.grab(group: 'org.apache.maven', module: 'maven-ant-tasks', version: '2.1.3', classLoader: this.class.classLoader.rootLoader)

Задачи Maven ANT являются AntLib, и их можно загрузить следующим образом: 

import groovy.xml.NamespaceBuilder
def ant = new AntBuilder()
def mvn = NamespaceBuilder.newInstance(ant, 'antlib:org.apache.maven.artifact.ant')
...