Программа Clojure читает свой собственный MANIFEST.MF - PullRequest
Новая
       18

Программа Clojure читает свой собственный MANIFEST.MF

5 голосов
/ 01 мая 2010

Как программа Clojure может найти свой собственный файл MANIFEST.MF (при условии, что он упакован в файл JAR).

Я пытаюсь сделать это с помощью функции "-main", но не могу найти класс для использования в следующем коде: 

  (.getValue
    (..
      (java.util.jar.Manifest.
        (.openStream
          (java.net.URL.
            (str
              "jar:"
              (..
                (class **WHAT-GOES-HERE**)
                getProtectionDomain
                getCodeSource
                getLocation)
              "!/META-INF/MANIFEST.MF"))))
      getMainAttributes)
    "Build-number"))

Спасибо.

Ответы [ 5 ]

3 голосов
/ 24 мая 2010

Это, кажется, работает надежно: 

(defn set-version
  "Set the version variable to the build number."
  []
  (def version
    (.getValue (.. (Manifest.
      (.openStream
        (URL.
          (str "jar:"
            (.getLocation
              (.getCodeSource
                (.getProtectionDomain org.example.myproject.thisfile)))
            "!/META-INF/MANIFEST.MF"))))
      getMainAttributes)
      "Build-number")))
2 голосов
/ 08 мая 2013

Вот читаемая версия, настолько простая, насколько я мог ее получить! 

(when-let [loc (-> (.getProtectionDomain clazz) .getCodeSource .getLocation)]
  (-> (str "jar:" loc "!/META-INF/MANIFEST.MF")
      URL. .openStream Manifest. .getMainAttributes
      (.getValue "Build-Number")))
2 голосов
/ 05 февраля 2013

Я считаю, что моя версия немного проще для глаз: 

(defn manifest-map
  "Returns the mainAttributes of the manifest of the passed in class as a map."
  [clazz]
  (->> (str "jar:"
           (-> clazz
               .getProtectionDomain 
               .getCodeSource
               .getLocation)
           "!/META-INF/MANIFEST.MF")
      clojure.java.io/input-stream
      java.util.jar.Manifest.
      .getMainAttributes
      (map (fn [[k v]] [(str k) v]))
      (into {})))

(get (manifest-map MyClass) "Build-Number")
1 голос
/ 17 января 2017

Существует также clj-manifest , который, по существу, предоставляет эту функцию, используя вызов, аналогичный другим ответам, найденным здесь.

0 голосов
/ 02 мая 2010

Я нашел ответ, который работает, но я открыт для предложений по его улучшению, в частности, для замены звонка на Class/forName. 

(defn -main [& args]
  (println "Version "
    (.getValue
      (..
        (Manifest.
          (.openStream
            (URL.
              (str
                "jar:"
                (..
                  (Class/forName "org.example.myproject.thisfile")
                  getProtectionDomain
                  getCodeSource
                  getLocation)
                "!/META-INF/MANIFEST.MF"))))
        getMainAttributes)
      "Build-number")))
...