XSLT: Как отменить вывод без сортировки по содержимому - PullRequest
Новая
       24

XSLT: Как отменить вывод без сортировки по содержимому

1 голос
/ 16 марта 2010

У меня есть список предметов: 

<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>

и я хочу в качестве вывода 

z
c
x
a

У меня нет информации о заказе в файле, и я просто хочу изменить строки. Последняя строка в исходном файле должна быть первой строкой в ​​выводе. Как я могу решить эту проблему с помощью XSLT без сортировки по содержимому элементов, что дало бы неправильный результат?

Ответы [ 4 ]

3 голосов
/ 16 марта 2010

Я представлю два решения XSLT :

I. XSLT 1.0 с рекурсией Обратите внимание, что это решение работает для любого набора узлов, а не только в случае, когда узлы являются родственными элементами :

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/*">
     <xsl:call-template name="reverse">
       <xsl:with-param name="pList" select="*"/>
     </xsl:call-template>
    </xsl:template>

    <xsl:template name="reverse">
      <xsl:param name="pList"/>

      <xsl:if test="$pList">
        <xsl:value-of
         select="concat($pList[last()], '&#xA;')"/>

        <xsl:call-template name="reverse">
          <xsl:with-param name="pList"
            select="$pList[not(position() = last())]"/>
        </xsl:call-template>
      </xsl:if>
    </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML : 

<t>
    <item>a</item>
    <item>x</item>
    <item>c</item>
    <item>z</item>
</t>

дает желаемый результат : 

z
c
x
a

II. Решение XSLT 2.0 : 

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>

  <xsl:template match="/*">
   <xsl:value-of select="reverse(*)/string(.)"
    separator="&#xA;"/>
  </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к тому же документу XML , , получается тот же правильный результат.

1 голос
/ 16 марта 2010

КОД XML: 

<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<device>
<element>a</element>
<element>x</element>
<element>c</element>
<element>z</element>
</device>

XSLT-код: 

<?xml version="1.0" encoding="ISO-8859-1"?>
<!-- Edited by XMLSpy® -->
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="//device">
<xsl:for-each select="element">

<xsl:sort select="position()" data-type="number" order="descending"/>

<xsl:text> </xsl:text>
<xsl:value-of select="."/>
<xsl:text> </xsl:text>
</xsl:for-each>
</xsl:template>

примечание: если вы используете data-type = "number", и любое из значений не является числом, эти нечисловые значения будут отсортированы перед числовыми значениями. Это означает, что если вы используете order = "ascending", нечисловые значения появляются первыми; если вы используете order = "убывающий", нечисловые значения появляются последними.

Обратите внимание , что нечисловые значения не были отсортированы; они просто появляются в выходном документе в том порядке, в котором они встречались.

также, вы можете найти это полезным для чтения:

http://docstore.mik.ua/orelly/xml/xslt/ch06_01.htm

1 голос
/ 16 марта 2010

Не уверен, как выглядит полный XML, поэтому я обернул элемент <doc>, чтобы он был правильно сформирован: 

<doc>
<item>a</item>
<item>x</item>
<item>c</item>
<item>z</item>
</doc>

Запуск этого примера XML для этой таблицы стилей: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
        <xsl:call-template name="reverse">
            <xsl:with-param name="item" select="doc/item[position()=last()]" />
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="reverse">
        <xsl:param name="item" />

        <xsl:value-of select="$item" />
        <!--Adds a line feed-->
        <xsl:text>&#10;</xsl:text>

        <!--Move on to the next item, if we aren't at the first-->
        <xsl:if test="$item/preceding-sibling::item">
            <xsl:call-template name="reverse">
                <xsl:with-param name="item" select="$item/preceding-sibling::item[1]" />
            </xsl:call-template>
        </xsl:if>

    </xsl:template>

</xsl:stylesheet>

Создает запрошенный вывод: 

z
c
x
a

Возможно, вам потребуется настроить xpath в соответствии с вашим фактическим XML.

0 голосов
/ 16 марта 2010

Рассмотрим этот ввод XML: 

<?xml version="1.0" encoding="utf-8" ?>
<items>
  <item>a</item>
  <item>x</item>
  <item>c</item>
  <item>z</item>
</items>

XSLT: 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="text" />

    <xsl:template match="/items[1]">

      <xsl:variable name="items-list" select="." />
      <xsl:variable name="items-count" select="count($items-list/*)" />

      <xsl:for-each select="item">
        <xsl:variable name="index" select="$items-count+1  - position()"/>
        <xsl:value-of select="$items-list/item[$index]"/>
        <xsl:value-of select="'&#x0a;'"/>
      </xsl:for-each>

    </xsl:template>
</xsl:stylesheet>

И результат: 

z
c
x
a
...