АНТЛР грамматика от бизона - PullRequest
Новая
       15

АНТЛР грамматика от бизона

2 голосов
/ 31 марта 2010

Я пытаюсь перевести грамматику с бизона на ANTLR. Сама грамматика довольно проста в зубрах, но я не могу найти простой способ сделать это.

Грамматика в зубрах: 

expr = expr or expr | expr and expr | (expr)

Любые подсказки / ссылки / указатели приветствуются.

Спасибо, Юлиан

1 Ответ

4 голосов
/ 31 марта 2010

В ANTLR нельзя создавать левые рекурсивные правила: 

a : a b
  ;

Хвостовая рекурсия в порядке: 

a : b a
  ;

Для получения дополнительной информации о левых рекурсивных правилах см. ANTLR's Wiki .

Итак, ваш пример может выглядеть так: 

parse
  :  expr+ EOF
  ;

expr
  :  orExpr
  ;

orExpr
  :  andExpr ('or' andExpr)*
  ;

andExpr
  :  atom ('and' atom)*
  ;

atom
  :  Boolean
  |  '(' expr ')'
  ;

Boolean
  :  'true'
  |  'false'
  ;

Вот небольшая демонстрация на Java: 

grammar BoolExp;

@members {
  public static void main(String[] args) throws Exception {
    if(args.length != 1) {
      System.out.println("Usage:");
      System.out.println(" - Windows    : java -cp .:antlr-3.2.jar BoolExpParser \"EXPRESSION\"");
      System.out.println(" - *nix/MacOS : java -cp .;antlr-3.2.jar BoolExpParser \"EXPRESSION\"");
      System.exit(0);
    }
    ANTLRStringStream in = new ANTLRStringStream(args[0]);
    BoolExpLexer lexer = new BoolExpLexer(in);
    CommonTokenStream tokens = new CommonTokenStream(lexer);
    BoolExpParser parser = new BoolExpParser(tokens);
    parser.parse();
  }
}

parse
  :  e=expr EOF {System.out.println($e.bool);}
  ;

expr returns [boolean bool]
  :  e=orExpr {$bool = $e.bool;}
  ;

orExpr returns [boolean bool]
  :  e1=andExpr       {$bool = $e1.bool;} 
     ('or' e2=andExpr {$bool = $bool || $e2.bool;}
     )*
  ;

andExpr returns [boolean bool]
  :  e1=atom        {$bool = $e1.bool;} 
     ('and' e2=atom {$bool = $bool && $e2.bool;}
     )*
  ;

atom returns [boolean bool]
  :  b=Boolean      {$bool = new Boolean($b.text).booleanValue();}
  |  '(' e=expr ')' {$bool = $e.bool;}
  ;

Boolean
  :  'true'
  |  'false'
  ;

Space
  :  (' ' | '\t' | '\n' | '\r') {skip();}
  ;

Сначала создайте лексер и парсер (1), а затем скомпилируйте все исходные файлы (2). Наконец, выполните BoolExpParser class (3).

1 

// Windows & *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool BoolExp.g

2 

// Windows
javac -cp .;antlr-3.2.jar *.java

// *nix/MacOS
javac -cp .:antlr-3.2.jar *.java

3 

// Windows
java -cp .;antlr-3.2.jar BoolExpParser "false and true or true"

// *nix/MacOS
java -cp .:antlr-3.2.jar BoolExpParser "false and true or true"

Теренс Парр Ссылка ANTLR - книга по ANTLR. И Скотт создал несколько превосходных видеоуроков на ANTLR 3 (с Eclipse).

...