Проход по списку в многострочной строке Groovy

Question

Я пытаюсь создать многострочную строку в Groovy. У меня есть список строк, которые я хотел бы перебрать в многострочном. Я не уверен, что синтаксис для этого. Что-то вроде ниже ...

    def html = """\
       <ul>
          <li>$awaiting.each { it.toPermalink()}</li>
       </ul>
     """

Answer 1

следующее:

class PLink {
  String name
  String toPermalink() {
    "link->$name"
  }
}
def awaiting = [ new PLink( name:'one' ), new PLink( name:'two' ), new PLink( name:'three' ) ]
def html = """<ul>
  <li>${awaiting.collect { it.toPermalink() }.join( "</li><li>" )}</li>
</ul>"""

Производит этот вывод:

<ul>
  <li>link->one</li><li>link->two</li><li>link->three</li>
</ul>

Он в основном вызывает метод для каждого элемента, collects результаты возвращаются в другой список, а затем joins список вместе в строку

Answer 2

Рассматривали ли вы использование MarkupBuilder? Они предоставляют действительно хороший способ построения HTML или XML, особенно если вы хотите встроить циклические конструкции или условную логику.

Например:

import groovy.xml.MarkupBuilder

def writer = new StringWriter()
def builder = new MarkupBuilder(writer)

def awaiting = ['one', 'two', 'three']

builder.html {
    ul {
        awaiting.each { 
            li(it.toString())
        }
    }
}

println writer.toString()

Результат:

* +1007 *