Визуализация последовательности узлов в виде таблицы M x N

Question

@ Одед: Извините, что в моей экспозиции было плохо ... Мой входной документ содержит такой фрагмент:

<recordset name="resId" >
<record n="0">example 1</record>
<record n="1">example 2</record>
<record n="2">example 1</record>
....
<record n="N">example 1</record>
</recordset>

, содержащий произвольно длинную последовательность узлов.Атрибут «n» сообщает о порядке узла в последовательности.Мне нужно упорядочить эту последовательность в виде таблицы M (строки) x N (столбцы), и у меня возникли некоторые проблемы с этим.Я не могу вызвать шаблон

<xsl:template match="recordset">
   <table>
      <xsl:apply-templates select="record"/>
   </table>
</xsl:template>

с чем-то вроде:

<xsl:template match="record">
<xsl:if test="@n mod 3 = 0">
    <tr>
</xsl:if>
........
<td><xsl:value-of select"something"></td>

, потому что код недействителен (и я должен каким-то образом повторить его в конце шаблона), и я долженположите некоторое (может быть, слишком) доверие в присутствии пронумерованного атрибута.У кого-то есть подсказка?Спасибо!

Answer 1

Вы должны убедиться, что вложение никогда не нарушается. Вещи, которые вы хотите вкладывать в выходные данные, должны быть вложены в XSLT.

<xsl:variable name="perRow" select="3" />

<xsl:template match="recordset">
  <table>
    <xsl:apply-templates 
      mode   = "tr"
      select = "record[position() mod $perRow = 1]"
    />
  </table>
</xsl:template>

<xsl:template match="record" mode="tr">
  <tr>
    <xsl:variable name="td" select="
      . | following-sibling::record[position() &lt; $perRow]
    " />
    <xsl:apply-templates mode="td" select="$td" />
    <!-- fill up the last row -->
    <xsl:if test="count($td) &lt; $perRow">
      <xsl:call-template name="filler">
        <xsl:with-param name="rest" select="$perRow - count($td)" />
      </xsl:call-template>
    </xsl:if>
  </tr>
</xsl:template>

<xsl:template match="record" mode="td">
  <td>
    <xsl:value-of select="." />
  </td>
</xsl:template>

<xsl:template name="filler">
  <xsl:param name="rest" select="0" />
  <xsl:if test="$rest">
    <td />
    <xsl:call-template name="filler">
      <xsl:with-param name="rest" select="$rest - 1" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>

Answer 2

Использование xslt 2.0

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes"/>
    <xsl:param name="rows">3</xsl:param>
    <xsl:template match="recordset">
        <table>
            <xsl:for-each-group select="record" group-by="count(preceding-sibling::*) mod $rows ">
                <xsl:value-of select="current-grouping-key()"/>
                <tr>
                    <xsl:for-each select="current-group()">
                        <td>
                            <xsl:apply-templates/>
                        </td>
                    </xsl:for-each>
                </tr>
            </xsl:for-each-group>
        </table>
    </xsl:template>
</xsl:stylesheet>

Answer 3

В XSLT 1.0, используя общий шаблон для каждой строки.

Если в качестве параметра указано имя элемента строки, шаблон n-per-row не привязан к формату ввода или вывода.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:output method="xml" indent="yes" />

  <xsl:template match="recordset">
    <table>
      <xsl:call-template name="n-per-row">
        <xsl:with-param name="select" select="record" />
        <xsl:with-param name="row-size" select="2"/>
        <xsl:with-param name="row-element" select="'tr'"/>
      </xsl:call-template>
    </table>
  </xsl:template>

  <xsl:template match="record">
    <xsl:copy-of select="."/>
  </xsl:template>

  <xsl:template name="n-per-row">
    <xsl:param name="select" />
    <xsl:param name="row-size" />
    <xsl:param name="row-element" />
    <xsl:param name="start">
      <xsl:text>1</xsl:text>
    </xsl:param>

    <xsl:variable name="count" select="count($select)" />
    <xsl:variable name="last-tmp" select="number($start) + number($row-size)" />
    <xsl:variable name="last">
      <xsl:choose>
        <xsl:when test="$last-tmp &gt; $count">
          <xsl:value-of select="$count"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$last-tmp"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>

    <xsl:element name="{$row-element}">
      <xsl:apply-templates select="$select[position() &lt;= $last]"/>
    </xsl:element>

    <xsl:if test="count($select) &gt; $last">
      <xsl:call-template name="n-per-row">
        <xsl:with-param name="select" select="$select[position() &gt; $last]"/>
        <xsl:with-param name="row-size" select="$row-size"/>
        <xsl:with-param name="row-element" select="$row-element"/>
        <xsl:with-param name="start" select="$start"/>
      </xsl:call-template>
    </xsl:if>

  </xsl:template>

</xsl:stylesheet>