Perl: рекурсивно переименовывает все файлы и каталоги

Question

Мне нужно рекурсивно переименовать каждый файл и каталог. Я преобразовываю пробелы в подчеркивания и делаю все имена файлов / каталогов строчными. Как сделать так, чтобы следующий скрипт переименовал все файлы за один прогон? В настоящее время сценарий необходимо запустить несколько раз, прежде чем все файлы / каталоги будут преобразованы. Код ниже:

#!/usr/bin/perl

use File::Find;

$input_file_dir = $ARGV[0];

sub process_file {
        $clean_name=lc($_);
        $clean_name=~s/\s/_/g;
        rename($_,$clean_name);
        print "file/dir name: $clean_name\n";
}
find(\&process_file, $input_file_dir);

Answer 1

Вам нужно либо указать bydepth => 1 в опциях, которые вы передаете, чтобы найти, либо позвонить finddepth. От perldoc File :: Find :

bydepth

Сообщает имя каталога только ПОСЛЕ того, как были сообщены все его записи. Точка входа finddepth() является ярлыком для указания { bydepth => 1 } в первом аргументе find().

Однако, вам все еще нужно решить, как бороться с именованными конфликтами, потому что переименование приведет к сбою цели, если цель существует .

#!/usr/bin/perl

use strict; use warnings;
use File::Find;

finddepth(\&process_file, $_) for @ARGV;

Answer 2

если вы открыты для других подходов, вот решение Python

import os
for R,DIR,FILES in os.walk("/mypath",topdown=False):
    for file in FILES:
        newfile=file.lower().replace(" ","_")
        new_file_name=os.path.join(R,newfile)
        os.rename( os.path.join(R,file) , new_file_name)
    for dir in DIR:
        newdir=dir.lower().replace(" ","_")
        new_dir_name=os.path.join(R,newdir)
        os.rename( os.path.join(R,dir) , new_dir_name)

Answer 3

Вы можете переименовать файлы перед обходом каталога.

find({
        preprocess => sub {
            for (@_) {
                my $oldname = $_;
                $_ = lc;
                s/\s/_/g;
                rename $oldname => $_;
            }
            return @_;
        },
        wanted => sub {
            print "$File::Find::name was already renamed\n";
        },
    },
    @dirs
);

Или вы можете отложить переименование до тех пор, пока не произойдет обход.

finddepth(sub {
        print "in $File::Find::dir, renaming $_\n";
        my $newname = lc;
        $newname =~ s/\s/_/g;
        rename $_ => $newname;
    },
    @dirs
);

Проблема, с которой вы сталкиваетесь, заключается в том, что

find находит каталог "Abc Def"
find звонки wanted("Abc Def")
rename "Abc Def" => "abc_def"
find пытается ввести "Abc Def", который больше не существует
так что все под не обрабатывается