Тестирование действий ввода-вывода с Monadic QuickCheck - PullRequest
Новая
       23

Тестирование действий ввода-вывода с Monadic QuickCheck

49 голосов
/ 14 февраля 2010

Может ли кто-нибудь дать мне краткий пример тестирования действий ввода-вывода с помощью Monadic QuickCheck?

Ответы [ 2 ]

57 голосов
/ 01 июня 2010

Модуль Test.QuickCheck.Monadic позволяет тестировать монадический код, даже если он работает в IO.

Тест на монадические свойства имеет тип PropertyM m a, где m - это монада, в которой выполняется тест, а a в конечном итоге игнорируется. В случае PropertyM IO a вы преобразуете монадический тест в Property, используя monadicIO; для всех остальных монад вместо этого вы используете monadic (что требует функции для запуска монады, чего нет у IO).

В монадическом тесте значение return ed вне монады игнорируется. Чтобы проверить выражение, используйте assert; assert Если ввести ложное значение, тест не пройден. Используйте run для выполнения кода в тестируемой монаде.

В вашем распоряжении другие монадические действия. Например, pick сгенерирует новые тестовые входы из Gen a, а pre проверит предварительные условия теста. Они полезны, если сами входные данные теста или предварительные условия зависят от значений, вычисленных с помощью тестируемой монады, и в этом случае нормальный способ генерации входных данных или проверки предварительных условий не будет работать.

Вот пример тестирования некоторого IO кода: мы проверяем, что после записи чего-либо во временный файл мы можем прочитать те же самые данные обратно. В демонстрационных целях мы навязываем предварительное условие, что мы записываем в файл хотя бы один байт. Два тестовых свойства делают одно и то же; один использует pick и pre без необходимости, а другой нет. 

import System.Directory (removeFile)
import System.IO (hGetContents, hPutStr, hSeek, openBinaryTempFile, SeekMode (..))
import Test.QuickCheck (arbitrary, Property, quickCheck, (==>))
import Test.QuickCheck.Monadic (assert, monadicIO, pick, pre, run)

-- Demonstrating pick and pre as well:
prop_writeThenRead :: Property
prop_writeThenRead = monadicIO $ do writtenData <- pick arbitrary
                                    pre $ not (null writtenData)
                                    readData <- run $ writeThenRead writtenData
                                    assert $ writtenData == readData

-- A more idiomatic way to write the above:
prop_writeThenRead2 :: [Char] -> Property
prop_writeThenRead2 writtenData = not (null writtenData) ==> monadicIO test
    where test = do readData <- run $ writeThenRead writtenData
                    assert $ writtenData == readData

writeThenRead :: [Char] -> IO [Char]
writeThenRead output = do (path, h) <- openBinaryTempFile "/tmp" "quickcheck.tmp"
                          removeFile path
                          hPutStr h output
                          hSeek h AbsoluteSeek 0
                          hGetContents h

main :: IO ()
main = do quickCheck prop_writeThenRead
          quickCheck prop_writeThenRead2
7 голосов
/ 15 февраля 2010

Стандартным эталоном для тестирования монадического кода является "Тестирование монадического кода с помощью QuickCheck" . Здесь показаны различные способы тестирования в контексте монады, такой как IO.

Но вам стоит подумать о том, чтобы опубликовать более конкретный вопрос о том, что вы хотели бы проверить.

...