Как использовать WMI с Delphi, не увеличивая при этом размер файла приложения?

Question

Я использую Delphi 2010, и когда я создал консольное приложение, которое печатает «Hello World», оно занимает 111 кб. Если я хочу запросить WMI с Delphi, я добавляю модули WBEMScripting_TLB, ActiveX и Variants в свой проект. Если я выполню простой запрос WMI, мой исполняемый размер увеличится до 810 КБ. I

Есть ли в любом случае запросить WMI без такого большого дополнения к размеру файла? Простите мое невежество, но почему у меня нет этой проблемы с C ++?

Вот мой код:

program WMITest;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  WBEMScripting_TLB,
  ActiveX,
  Variants;

function GetWMIstring(wmiHost, root, wmiClass, wmiProperty: string): string;
var
  Services: ISWbemServices;
  SObject: ISWbemObject;
  ObjSet: ISWbemObjectSet;
  SProp: ISWbemProperty;
  Enum: IEnumVariant;
  Value: Cardinal;
  TempObj: OLEVariant;
  loc: TSWbemLocator;
  SN: string;
  i: integer;
begin
  Result := '';
  i := 0;
  try
    loc := TSWbemLocator.Create(nil);
    Services := Loc.ConnectServer(wmiHost, root {'root\cimv2'}, '', '', '', '',
      0, nil);
    ObjSet := Services.ExecQuery('SELECT * FROM ' + wmiClass, 'WQL',
      wbemFlagReturnImmediately and wbemFlagForwardOnly, nil);
    Enum := (ObjSet._NewEnum) as IEnumVariant;
    if not VarIsNull(Enum) then
      try
        while Enum.Next(1, TempObj, Value) = S_OK do
        begin
          try
            SObject := IUnknown(TempObj) as ISWBemObject;
          except SObject := nil;
          end;
          TempObj := Unassigned;
          if SObject <> nil then
          begin
            SProp := SObject.Properties_.Item(wmiProperty, 0);
            SN := SProp.Get_Value;
            if not VarIsNull(SN) then
            begin
              if varisarray(SN) then
              begin
                for i := vararraylowbound(SN, 1) to vararrayhighbound(SN, 1) do
                  result := vartostr(SN[i]);
              end
              else
                Result := SN;
              Break;
            end;
          end;
        end;
        SProp := nil;
      except
        Result := '';
      end
    else
      Result := '';
    Enum := nil;
    Services := nil;
    ObjSet := nil;
  except
    on E: Exception do
      Result := e.message;
  end;
end;

begin
  try
    WriteLn('hello world');
    WriteLn(GetWMIstring('.', 'root\CIMV2', 'Win32_OperatingSystem',
      'Caption'));
    WriteLn('done');

  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

UPDATE: Когда я компилирую следующий пример из MSDN с Microsoft Visual C ++ 2008 (консольное приложение), это 76 КБ.

Answer 1

@ Мик, вы можете получить доступ к WMI без импорта сценария WBEMS из Delphi, используя интерфейсы IBindCtx и IMoniker .

Проверьте этот простой код (протестировано в Delphi 2010 и Windows 7), размер исполняемого файла составляет 174 КБ.

program WmiTest;

{$APPTYPE CONSOLE}


uses
  SysUtils
  ,ActiveX
  ,ComObj
  ,Variants;


function GetWMIstring(wmiHost, root, wmiClass, wmiProperty: string): string;
var
  objWMIService : OLEVariant;
  colItems      : OLEVariant;
  colItem       : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;

  function GetWMIObject(const objectName: String): IDispatch;
  var
    chEaten: Integer;
    BindCtx: IBindCtx;//for access to a bind context
    Moniker: IMoniker;//Enables you to use a moniker object
  begin
    OleCheck(CreateBindCtx(0, bindCtx));
    OleCheck(MkParseDisplayName(BindCtx, StringToOleStr(objectName), chEaten, Moniker));//Converts a string into a moniker that identifies the object named by the string
    OleCheck(Moniker.BindToObject(BindCtx, nil, IDispatch, Result));//Binds to the specified object
  end;

begin
  objWMIService := GetWMIObject(Format('winmgmts:\\%s\%s',[wmiHost,root]));
  colItems      := objWMIService.ExecQuery(Format('SELECT * FROM %s',[wmiClass]),'WQL',0);
  oEnum         := IUnknown(colItems._NewEnum) as IEnumVariant;
  while oEnum.Next(1, colItem, iValue) = 0 do 
  begin
     Result:=colItem.Properties_.Item(wmiProperty, 0); //you can improve this code  ;) , storing the results in an TString.
  end;
end;

begin
 try
    CoInitialize(nil);
    try         
      WriteLn(GetWMIstring('.', 'root\CIMV2', 'Win32_OperatingSystem','Caption'));
      Readln;
    finally
    CoUninitialize;
    end;
 except
    on E:Exception do
    Begin
        Writeln(E.Classname, ': ', E.Message);
        Readln;
    End;
  end;
end.

Answer 2

ActiveX и / или варианты добавят максимум 36 КБ.
Это WBEMScripting_TLB , которое добавляет примерно 650KB к вашему проекту.
Он не огромен в строках кода, но более чем декларирует немало классов, интерфейсов и констант, он включает в себя OleServer .
И , что приносит целую Controls единицу с ее тяжелым багажом .

Answer 3

когда delphi создает исполняемый файл, он статически связывается в библиотеках времени выполнения delphi. это приводит к увеличению размера исполняемого файла, однако, поскольку rtl статически связан, развертывание становится проще, и есть элемент проверки будущего.

Вы можете настроить delphi для использования пакетов времени выполнения, включив Build with runtime packages в Project / Options. однако вы должны убедиться, что пакеты delphi rtl доступны, и у вас могут возникнуть проблемы с отладкой.

это статическое поведение в сравнении с поведением во время выполнения, вероятно, объясняет различия, которые вы видите между delphi и c ++.

Answer 4

Разница, которую вы видите, в любом случае частично заключается в том, что VC ++ по умолчанию использует динамически связанные библиотеки времени выполнения; библиотеки времени выполнения загружаются из библиотек DLL при запуске приложения, и поэтому код отсутствует в исполняемом файле.

Delphi, OTOH, по умолчанию ссылки на весь код библиотеки времени выполнения, если только вы не строите с включенными пакетами времени выполнения. Эта разница в конфигурациях по умолчанию будет составлять большинство различий в размерах исполняемых файлов.

Answer 5

Ну, я не знаю о WBEMScripting_TLB, но ActiveX.pas - довольно большой модуль. Это почти 7000 строк на моей установке D2010. Если вам нужно внести какое-то значительное количество этого в ваш код, то вы можете ожидать, что он добавит несколько сотен килограмм к вашему размеру EXE.

Кстати, насколько велик TLB?