Для одного элемента это довольно простой запрос с использованием подзапросов SPARQL 1.1. Хитрость заключается в том, чтобы упорядочить ревизии, которые имеют данное свойство, по дате и взять значение из последней ревизии. Форма values используется только для указания элементов, которые вы выбираете. Если вам нужно запросить дополнительные элементы, вы можете добавить их в блок values.
prefix mymeta: <http://www.mymeta.com/meta/>
prefix dc: <http://purl.org/dc/elements/1.1/>
select ?item ?title ?format ?extent where {
values ?item { <urn:ITEMID:12345> }
#-- Get the title by examining all the revisions that specify a title,
#-- ordering them by date, and taking the latest one. The same approach
#-- is used for the format and extent.
{ select ?title { ?item mymeta:itemchange [ dc:title ?title ; dc:issued ?date ] . }
order by desc(?date) limit 1 }
{ select ?format { ?item mymeta:itemchange [ dc:format ?format ; dc:issued ?date ] . }
order by desc(?date) limit 1 }
{ select ?extent { ?item mymeta:itemchange [ dc:extent ?extent ; dc:issued ?date ] . }
order by desc(?date) limit 1 }
}
$ sparql --data data.n3 --query query.rq
----------------------------------------------------------------------------------
| item | title | format | extent |
==================================================================================
| <urn:ITEMID:12345> | "Improved Product Name"@en | "4 x 6 x 1 in"@en | "200"@en |
----------------------------------------------------------------------------------
Если вам действительно нужно сделать это для всех элементов, вы можете использовать другой подзапрос для выбора элементов. То есть вместо values ?item { ... } используйте:
{ select ?item { ?item a mymeta:item } }
Хотя это не было упомянуто в исходном вопросе, это в комментариях , если вы хотите получить самые последние значения свойств для всех свойств, вы можете выполнить подзапрос, как следующее, основанное на Как ограничить размер группы решений SPARQL?
select ?item ?property ?value {
values ?item { <urn:ITEMID:12345> }
?item mymeta:itemchange [ ?property ?value ; dc:issued ?date ]
#-- This subquery finds the earliest date for each property in
#-- the graph for each item. Then, outside the subquery, we
#-- retrieve the particular value associated with that date.
{
select ?property (max(?date_) as ?date) {
?item mymeta:itemchange [ ?property [] ; dc:issued ?date_ ]
}
group by ?item ?property
}
}
---------------------------------------------------------------
| item | property | value |
===============================================================
| <urn:ITEMID:12345> | dc:issued | "2007-06-01"@en |
| <urn:ITEMID:12345> | dc:title | "Improved Product Name"@en |
| <urn:ITEMID:12345> | dc:extent | "200"@en |
| <urn:ITEMID:12345> | dc:format | "4 x 6 x 1 in"@en |
---------------------------------------------------------------