Перечисление строки - PullRequest
Новая
       6

Перечисление строки

0 голосов
/ 18 марта 2010

У меня есть статус, который хранится в виде строки заданной длины, либо в файле, либо в базе данных.

Я хочу перечислить возможный статус '

У меня есть следующий тип, чтобы определить возможный статус '

Type TStatus = (fsNormal = Ord('N'),fsEditedOnScreen = Ord('O'),
                fsMissing = Ord('M'),fsEstimated = Ord('E'),fsSuspect = Ord('s'),
                fsSuspectFromOnScreen = Ord('o'),fsSuspectMissing = Ord('m'),
                fsSuspectEstimated = Ord('e'));

Во-первых, это действительно хорошая идея? или я должен иметь отдельный массив const, хранящий преобразования символов? Это будет означать более одного места для обновления.

Теперь преобразовать строку в массив состояния. У меня есть следующее, но как я могу проверить, является ли символ действительным, не проходя через перечисление? 

Function StrToStatus(Value : String):TStatusArray;
var
    i: Integer;
begin
    if Trim(Value) = '' then
    begin
        SetLength(Result,0);
        Exit;
    end;
    SetLength(Result,Length(Value));
    for i := 1 to Length(Value) do
    begin
        Result[i] := TStatus(Value[i]); // I don't think this line is safe.
    end;
end;

После некоторого тестирования он все же подозревает, что подозрительная строка безопасна (она не падает!), А просто добавляет (выходит за пределы) значения, которые затем необходимо отфильтровать. 

Function StrToStatus(Value : String):TStatusArray;
var
    i: Integer;
begin
    if Trim(Value) = '' then
    begin
        SetLength(Result,0);
        Exit;
    end;
    SetLength(Result,Length(Value));
    for i := 1 to Length(Value) do
    begin
        Result[i-1] := TStatus(Value[i]);
    end;
    for i := 0 to Length(Result) - 1 do
    begin
        case Result[i] of
            fsNormal: ;
            fsEditedOnScreen: ;
            fsMissing: ;
            fsEstimated: ;
            fsSuspect: ;
            fsSuspectFromOnScreen: ;
            fsSuspectMissing: ;
            fsSuspectEstimated: ;
            else
                Result [i] := fsNormal;
        end;
    end;
end;

Это позволяет всем статусам 'и их относительным значениям Char находиться в одном месте и предотвращает циклический просмотр каждого статуса для каждого символа в строке. (Так что в моей голове по крайней мере должно быть немного быстрее)

AFAIK это должно быть хорошо для обратного преобразования. 

Function StatusToStr(Value : TStatusArray):String;
var
  i: Integer;
begin
    for i := 0 to Length(Value) - 1 do
        Result := Result + Chr(Ord(Value[i]))
end;

Я использую Delphi 2007

Ответы [ 2 ]

2 голосов
/ 18 марта 2010

Если я вас правильно понял, я бы заменил массив на набор и использовал бы перечисление без явных значений, например: 

program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TStatus = (fsNormal, fsEditedOnScreen, fsMissing, fsEstimated, fsSuspect,
    fsSuspectFromOnScreen, fsSuspectMissing, fsSuspectEstimated);
  TStatusSet = set of TStatus;

const
  cStatusChars: array[TStatus] of Char = ('N', 'O', 'M', 'E', 's', 'o', 'm', 'e');

function CharToStatus(AChar: Char; out AStatus: TStatus): Boolean;
var
  st: TStatus;
begin
  for st := Low(TStatus) to High(TStatus) do
    if cStatusChars[st] = AChar then
    begin
      AStatus := st;
      Result := True;
      Exit;
    end;
  Result := False;
end;

function StrToStatus(const Value: string): TStatusSet;
var
  i: Integer;
  st: TStatus;
begin
  Result := [];
  for i := 1 to Length(Value) do
    if CharToStatus(Value[i], st) then
      Include(Result, st);
end;

function StatusToStr(const Value: TStatusSet): string;
var
  st: TStatus;
begin
  for st in Value do
    Result := Result + cStatusChars[st];
end;

var
  StatusSet: TStatusSet;
begin
  StatusSet := StrToStatus('EmO');
  Writeln(StatusToStr(StatusSet));
  Readln;
end.
0 голосов
/ 18 марта 2010

Во-первых, мне интересно, почему вы сохраняете это как строку, а не как целое число.

То, как вы это сделали, единственный способ сделать это правильно - это иметь условие Case ... 

function CharToStatus(AChar : Char):TStatus;
begin
  case AChar of
    'N' : Result := fsNormal;
    'O' : Result := fsEditedOnScreen;
    'M' : Result := fsMissing;
    'E' : Result := fsEstimated;
    's' : Result := fsSuspect;
    'o' : Result := fsSuspectFromOnScreen;
    'm' : Result := fsSuspectMissing;
    'e' : Result := fsSuspectEstimated;
  else
    //Manage error;
  end;
end;

function StatusToChar(AStatus : TStatus) : char;
begin
  Result := Char(AStatus);
end;

Выражение x in [Low(TStatus)]..High(Tstatus)] не будет работать в этой ситуации. Причина этого в том, что Low (TStatus) = 'E', а High (TStatus) = 's'. Все промежуточное будет считаться действительным. (то есть «Z» находится в [Низкий (Tstatus)] .. Высокий (Tstatus)])

Выражение x in [Low(TStatus)]..High(Tstatus)] работает только с типом, в котором нет "дыры" в объявлении. (Как и без явных значений, где первый элемент равен 0, 2-й - 1, 3-й - 2 ... и т. Д.)

// EDIT

Хорошо ... если подумать о проблеме немного дальше, я не понимаю, почему вам не нравится подход с использованием константного массива ... Что-то вроде этого было бы намного лучше. 

type
  TStatus = (fsNormal, fsEditedOnScreen,
                fsMissing,fsEstimated,fsSuspect,
                fsSuspectFromOnScreen,fsSuspectMissing ,
                fsSuspectEstimated);
const
  StatusValue : Array[TStatus] of Char = ('N','O','M','E','s','o','m','e');

function StatusValueToTStatus(C : Char) : TStatus;
var I : Integer;
begin
  for I := Low(StatusValue) to High(StatusValue)  do
  begin
    if StatusValue = C then
    begin
      Result := TStatus(I);
      EXIT;
    end;
  end;
  //Not found, Manage errors
end;
...