Как правильно отключить бот Bot :: BasicBot (на основе POE :: Component :: IRC)? - PullRequest
Новая
       34

Как правильно отключить бот Bot :: BasicBot (на основе POE :: Component :: IRC)?

3 голосов
/ 18 марта 2010

Это пример сценария. Когда я нажимаю Ctrl + C, бот выходит из IRC, но через некоторое время он снова подключается. Как правильно закрыть бот? 

#!/usr/bin/perl

package main;

my $bot = Perlbot->new (server => 'irc.dal.net');

$SIG{'INT'} = 'Handler';
$SIG{'TERM'} = 'Handler';

sub Handler {
print "\nShutting down bot...\n";
$bot->shutdown('Killed.');
};

$bot->run;

package Perlbot;
use base qw(Bot::BasicBot);

sub connected {
my $self = shift;
$self->join('#codetestchan');
}

Ответы [ 2 ]

2 голосов
/ 30 июля 2010

Я взял на себя сопровождение Bot :: BasicBot, и с версии 0.82 вы можете правильно отключить его с помощью $bot->shutdown($quit_message).

0 голосов
/ 16 апреля 2010

Изучив документацию и исходный код Bot :: BasicBot, я не могу найти изящный способ его выключить. Как вы продемонстрировали, вызов $bot->shutdown() (который фактически отправляет событие shutdown на POE::Component::IRC) просто вызовет повторное соединение Bot::BasicBot (кстати, с $bot->quit()).

Это и другие ограничения, с которыми столкнулись пользователи, заставили меня рекомендовать использовать POE::Component::IRC напрямую. В настоящее время имеется множество плагинов для функций, предоставляемых Bot::BasicBot, которые отсутствовали при создании Bot::BasicBot. Хотя вам, возможно, придется набрать немного больше, чтобы запустить базового бота, у вас гораздо больше гибкости. Ниже показан бот, похожий на тот, что в вашем примере, без использования Bot::BasicBot. Когда вы нажмете CTRL + C, он отправит сообщение о выходе на IRC-сервер, подождите, пока оно не будет отключено, а затем выйдите: 

#!/usr/bin/env perl

use strict;
use warnings;
use POE;
use POE::Component::IRC::State;
use POE::Component::IRC::Common qw(parse_user);
use POE::Component::IRC::Plugin::Connector;
use POE::Component::IRC::Plugin::AutoJoin;

# create our session
POE::Session->create(
    package_states => [
        # event handlers
        (__PACKAGE__) => [qw(_start int irc_join irc_disconnected)]
    ]
);

# start the event loop
POE::Kernel->run();

# session start handler
sub _start {
    my ($kernel, $heap) = @_[KERNEL, HEAP];

    # handle CTRL+C
    $kernel->sig(INT => 'int');

    # create bot object
    my $irc = POE::Component::IRC::State->spawn(
        server => 'irc.freenode.net',
        nick   => 'basic123bot',
        debug  => 1,
    );

    # save $irc in our session's storage heap
    $heap->{irc} = $irc;

    # handle reconnects
    $irc->plugin_add('Connector', POE::Component::IRC::Plugin::Connector->new());

    # handle channel joining
    $irc->plugin_add('AutoJoin', POE::Component::IRC::Plugin::AutoJoin->new(
        Channels => ['#foo123bar'],
    ));

    # connect to IRC
    $irc->yield('connect');
}

# interrupt signal handler
sub int {
    my ($kernel, $heap) = @_[KERNEL, HEAP];

    $heap->{irc}->yield('quit', 'Quitting, bye!');
    $heap->{shutting_down} = 1;
    $kernel->sig_handled();
}

# join handler
sub irc_join {
    my ($who, $chan) = @_[ARG0, ARG1];
    my $irc = $_[HEAP]->{irc};

    my ($nick, $user, $host) = parse_user($who);
    if ($nick eq $irc->nick_name()) {
        # say hello to channel members
        $irc->yield('privmsg', $chan, 'Hello everybody');
    }
}

# disconnect handler
sub irc_disconnected {
    my ($heap) = $_[HEAP];

    # shut down if we disconnected voluntarily
    $heap->{irc}->yield('shutdown') if $heap->{shutting_down};
}
...