Программно изменить форму запуска при запуске приложения?

Question

Могу ли я программно изменить форму запуска при запуске приложения в VB.Net?

Answer 1

Конечно, вы можете!

В свойствах вашего проекта установите для параметра Startup Object значение Sub Main и убедитесь, что в вашем приложении есть метод Public Sub Main. Хорошим вариантом может быть отдельный класс запуска:

Public Class myStartupClass

''' <summary>
''' This is the method that will be run when the application loads, 
''' because Project Properties, Startup Object is set to SubMain
''' </summary>
''' <remarks>
''' </remarks>
''' --------------------------------------------------------------------------------
Public Shared Sub Main()

    'The form that we will end up showing
    Dim formToShow As System.Windows.Forms.Form = Nothing

    'The determiner as to which form to show
    Dim myMood As String = "Happy"

    'Choose the appropriate form
    Select Case myMood
        Case "Happy"
            formToShow = New Form1
        Case Else
            formToShow = New Form2
    End Select

    'Show the form, and keep it open until it's explicitly closed.
    formToShow.ShowDialog()

End Sub

End Class

Answer 2

В «приложении Windows Forms», созданном в VB 2010 Express, вы можете сделать следующее в ApplicationEvents.vb:

Partial Friend Class MyApplication

    Private Sub MyApplication_Startup(ByVal sender As Object, ByVal e As Microsoft.VisualBasic.ApplicationServices.StartupEventArgs) Handles Me.Startup

       'Select the form of your choice
       My.Application.MainForm = Any_Form_You_like

    End Sub

End Class

Answer 3

Я использую этот подход, который эффективно запускает форму, как обычную точку входа приложения.

Public Sub Main()
    Dim value As String = Trim(Environment.CommandLine)
    Dim f As Form
    Select Case value
        Case "a"
            f = New frmTextEdit
        Case "b"
            f = New frmListDialog
        Case "c"
            f = New frmSuggestion
        Case Else
            Throw New Exception("Unsupported startup form option")
    End Select
    Application.Run(f)
End Sub