Как выбрать отдельные значения из документа XML с помощью XPATH?

Question

Как я могу выбрать только отдельные элементы для документа XML с использованием XPATH? Я пытался использовать функцию «разные значения», но по какой-то причине это не сработало ..

XML похож на следующее:

<catalog>

<product>
<size>12</size>
<price>1000</price>
<rating>1</rating>
</product>

<product>
<size>10</size>
<price>1000</price>
<rating>1</rating>
<year>2010</year>
</product>

</catalog>

Итак, я хочу получить список различных дочерних элементов всех элементов продукта. В данном примере это будет - размер, цена, рейтинг, год Мой xpath был что-то вроде: Different-values ​​(catalog / product / *)

Answer 1

В XPath 2.0 :

distinct-values(/*/*/*/name(.))

В XPath 1.0 это не может быть создано с одним выражением XPath .

Использование XSLT 1.0 :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/">
   <xsl:for-each select=
   "/*/*/*[not(../following::*/*
                       [not(name() = name(current()))]
               )
           ]">
     <xsl:value-of select="concat(name(), ' ')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу, получается требуемый результат :

size price rating year

Более эффективное преобразование XSLT 1.0 с использованием ключей :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="kpchildByName"
  match="product/*" use="name()"/>

 <xsl:template match="/">
   <xsl:for-each select=
   "/*/*/*
         [generate-id()
         =
          generate-id(key('kpchildByName', name())[1])
          ]">
     <xsl:value-of select="concat(name(), ' ')"/>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

Answer 2

Вам нужны различные значения имен элементов - что-то вроде:

distinct-values($catalog/product/*/name(.))

Answer 3

distinct-values() доступно в XPath 2.0. Вы используете это?

Если distinct-values() недоступно, стандартный способ получения различных значений - использовать not(@result = preceding:: @result) для получения уникального @result Это даст вам только первое вхождение.