программа по сборке - PullRequest
Новая
       34

программа по сборке

1 голос
/ 20 мая 2010

Может кто-нибудь объяснить, что делает эта программа? 

.= torg + 1000

main:
        mov pc, sp
        tst –(sp)

        mov #list1, -(sp)
        jsr pc, mystery
        mov r0, res1
        tst (sp)+

        mov #list2, -(sp)
        jsr pc, mystery
        mov r0, res2
        tst (sp)+

        halt


mystery:
        mov r1, -(sp)
        mov r4, -(sp)
        mov r5, -(sp)

        clr r0

        mov 10(sp), r4
        mov r4, r5

loop:
        mov r4, r1
        jsr pc, next
        mov r1, r4
        beq return

        mov r5, r1
        jsr pc, next
        jsr pc, next
        mov r1, r5
        beq return

        cmp r4, r5
        beq setret
        br loop

setret:
        inc r0

return:
        mov (sp)+, r5
        mov (sp)+, r4
        mov (sp)+, r1
        rts pc


next:
        tst r1
        beq abort
        mov (r1), r1
abort:
        rts pc


.= torg + 3000
list1: .word 3006, 3000, 3002, 3004, 0
res1: .word -1

.= torg + 3020
list2: .word 3030, 3026, 0, 3024, 3022
res2: .word -1

Я не могу понять этот фрагмент, спасибо всем заранее 

mystery:
            mov r1, -(sp)
            mov r4, -(sp)
            mov r5, -(sp)

            clr r0

            mov 10(sp), r4
            mov r4, r5

Ответы [ 2 ]

0 голосов
/ 20 мая 2010 
        mov r1, -(sp)
        mov r4, -(sp)
        mov r5, -(sp)

Это помещает три регистра в стек. 

        clr r0

Очевидные. 

        mov 10(sp), r4
        mov r4, r5

Это извлекает параметр из стека в r4 (а затем копирует его в r5).

0 голосов
/ 20 мая 2010

Похоже, что выполняется резервное копирование регистров 1, 4 и 5 и инициализация регистра 0 (резервное копирование не требуется). Поскольку @mystery является пунктом назначения jsr, это называется код пролога . Затем они инициализируются для цикла.

Старые значения восстанавливаются на @return.

Что касается всей программы, то, по-видимому, она находит циклические ссылки в связанном списке. 

bool is_invalid_list( link_node *l ) {
    while ( l && l->next && l->next->next ) {
        if ( l->next == l->next->next ) return true;
    }
    return false;
}

Я не думаю, что это самый простой или лучший способ реализовать это, но и не самый худший.

...