Определите «правильно».
i18n сортировка полностью зависит от вашей локали.
Поэтому я полностью согласен с PA в том, что это не ошибка: поведение по умолчанию Sort работает так, как предусмотрено, чтобы i18n работал правильно.
Как Джерри упоминает, TStringList.Sort использует AnsiCompareStr и AnsiCompareText (я объясню в нескольких строках, как это происходит что).
Но: TStringList является гибким, он содержит Сортировка , CustomSort и CompareStrings , которые все являются виртуальными (поэтому вы можете переопределить их в классе-потомке)
Кроме того, когда вы вызываете CustomSort , вы можете подключить свою собственную функцию Compare .
В этом ответе есть функция Compare , которая делает то, что вы хотите:
- Чувствительный к регистру
- Не используется ни одна локаль
- Просто сравните порядковый номер символов строк
CustomSort определяется следующим образом:
procedure TStringList.CustomSort(Compare: TStringListSortCompare);
begin
if not Sorted and (FCount > 1) then
begin
Changing;
QuickSort(0, FCount - 1, Compare);
Changed;
end;
end;
По умолчанию метод Sort имеет очень простую реализацию, передавая по умолчанию Compare функцию с именем StringListCompareStrings :
procedure TStringList.Sort;
begin
CustomSort(StringListCompareStrings);
end;
Итак, если вы определите свой собственный TStringListSortCompare совместимый Сравните метод, то вы можете определить свою собственную сортировку.
TStringListSortCompare определяется как глобальная функция, принимающая TStringList и два индекса, ссылающихся на элементы, которые вы хотите сравнить:
type
TStringListSortCompare = function(List: TStringList; Index1, Index2: Integer): Integer;
Вы можете использовать StringListCompareStrings в качестве руководства для реализации своих собственных:
function StringListCompareStrings(List: TStringList; Index1, Index2: Integer): Integer;
begin
Result := List.CompareStrings(List.FList^[Index1].FString,
List.FList^[Index2].FString);
end;
Итак, по умолчанию TStringList.Sort откладывается до TList.CompareStrings:
function TStringList.CompareStrings(const S1, S2: string): Integer;
begin
if CaseSensitive then
Result := AnsiCompareStr(S1, S2)
else
Result := AnsiCompareText(S1, S2);
end;
Который затем использует базовую функцию Windows API CompareString с языком пользователя по умолчанию LOCALE_USER_DEFAULT :
function AnsiCompareStr(const S1, S2: string): Integer;
begin
Result := CompareString(LOCALE_USER_DEFAULT, 0, PChar(S1), Length(S1),
PChar(S2), Length(S2)) - 2;
end;
function AnsiCompareText(const S1, S2: string): Integer;
begin
Result := CompareString(LOCALE_USER_DEFAULT, NORM_IGNORECASE, PChar(S1),
Length(S1), PChar(S2), Length(S2)) - 2;
end;
Наконец, Сравните нужную вам функцию. Опять ограничения:
- Чувствительный к регистру
- Не используется ни одна локаль
- Просто сравните порядковый номер символов строк
Это код:
function StringListCompareStringsByOrdinalCharacterValue(List: TStringList; Index1, Index2: Integer): Integer;
var
First: string;
Second: string;
begin
First := List[Index1];
Second := List[Index2];
if List.CaseSensitive then
Result := CompareStr(First, Second)
else
Result := CompareText(First, Second);
end;
Delphi не закрыт, скорее наоборот: часто это действительно гибкая архитектура.
Часто нужно немного покопаться, чтобы увидеть, где можно воспользоваться такой гибкостью.
- Йерун