Как я могу создать имя переменной Perl на основе строки? - PullRequest
Новая
       61

Как я могу создать имя переменной Perl на основе строки?

7 голосов
/ 16 февраля 2010

Можно ли в Perl создать глобальную переменную на основе строки?

Например, если бы у меня была такая функция: 

sub create_glob_var {
    my ($glob_var_str) = @_;
    # something like this ( but not a hash access).
    our ${$glob_var_str};
};

, и я назвал ее следующим образом: 

create_glob_var( "bar" );

Как я могу изменить create_glob_var, чтобы фактически создать глобальную переменную с именем $bar?

Мой проект использует Perl 5.8.5.

EDIT

Следующее не работает: 

use strict;
BEGIN {
  sub create_glob_var {
    my ($glob_var_str) = @_;
    no strict 'refs';
    $$glob_var_str = undef;  # or whatever you want to set it to
  }

  create_glob_var("bah");
};

$bah = "blah";

Производит: 

Variable "$bah" is not imported at /nfs/pdx/home/rbroger1/tmp2.pl line 12.
Global symbol "$bah" requires explicit package name at /nfs/pdx/home/rbroger1/tmp2.pl line 12.
Execution of /nfs/pdx/home/rbroger1/tmp2.pl aborted due to compilation errors.

NOTE Я понимаю, что с помощью глобальных переменныхвызывает разрушение озона и облысение у мужчин .Я пытаюсь очистить некоторый устаревший код, который уже полностью заражен с использованием глобальных переменных.По одному рефактору за раз ...

Ответы [ 6 ]

5 голосов
/ 16 февраля 2010

Если вы пытаетесь очистить старый код, вы можете написать модуль, который экспортирует необходимые переменные. Каждый раз, когда вы чувствуете необходимость вызвать create_glob_var, вместо этого добавьте переменную в этот пакет и поместите ее в список импорта.

Это поможет вам отслеживать, что происходит и как используются переменные. 

package MyVars;

use strict; use warnings;

use Exporter 'import';

our($x, %y, @z);

our @EXPORT_OK = qw( $x %y @z );

Сценарий: 

#!/usr/bin/perl

use strict;use warnings;

use MyVars qw( $x %y @z );

$x = 'test';
%y = (a => 1, b => 2);
@z = qw( a b c);

use Data::Dumper;
print Dumper \($x, %y, @z);

Выход: 

$VAR1 = \'test';
$VAR2 = {
          'a' => 1,
          'b' => 2
        };
$VAR3 = [
          'a',
          'b',
          'c'
        ];
3 голосов
/ 16 февраля 2010 
sub create_glob_var {
    my ($glob_var_str) = @_;
    no strict 'refs';
    $$glob_var_str = undef;  # or whatever you want to set it to
}

no strict 'refs' необходим, только если действует use strict, что всегда должно быть.

Добавление:

Если вы спрашиваете, есть ли способ написать подпрограмму create_glob_var, чтобы следующий код завершился успешно: 

use strict;
create_glob_var("bar");
$bar = "whatever";

... тогда ответ "Нет" Однако прагма Perl vars сделает то, что вы хотите: 

use strict;
use vars qw($bar);
$bar = "whatever";

Но это своего рода кодирование Perl в старом стиле. В настоящее время обычно делают это: 

use strict;
our $bar = "blah";

our также может просто объявить глобальные переменные, которые могут быть свободно использованы позже: 

our ($foo, @bar, %baz);
# ...
$foo = 5;
@bar = (1, 2, 3);
%baz = (this => 'that');
2 голосов
/ 16 февраля 2010

Прагма vars уже делает тяжелую работу для того, что вы хотите, поэтому включите ее в работу: 

#! /usr/bin/perl

use warnings;
use strict;
use vars;

BEGIN { vars->import(qw/ $bah /) }

$bah = "blah";
print $bah, "\n";

Если вы предпочитаете произносить его по буквам create_glob_var, тогда используйте 

#! /usr/bin/perl

use warnings;
use strict;
use vars;

sub create_glob_var { vars->import("\$$_[0]") }

BEGIN { create_glob_var "bah" }

$bah = "blah";
print $bah, "\n";

В любом случае, вывод 

blah

Мне любопытно узнать, почему вы хотите сделать это таким образом, вместо того, чтобы объявлять эти переменные с помощью our. Да, может потребоваться несколько итераций, чтобы поймать их всех, но это все равно краткосрочные исправления, верно?

В общем, вы можете использовать переменную в качестве имени переменной (см. «Символические ссылки» в perlref ), но вы действительно, действительно, действительно не хотите делать что: включение прагмы strict 'refs' отключает эту функцию.

Рафаэль Гарсиа-Суарес проявил великую мудрость, когда написал: «Я не знаю, в чем ваша изначальная проблема, но я предлагаю использовать хеш».

Смотри также:

2 голосов
/ 16 февраля 2010

Попробуйте посмотреть на этот вопрос: Есть ли в Perl динамические переменные, подобные PHP?

Короче говоря, похоже, что вы должны быть в состоянии сделать $$glob_var_str = "whatever";

2 голосов
/ 16 февраля 2010

Вы должны использовать eval, но это обычно считается злом.Примерно так:

eval("$glob_var_str = \@_;");

РЕДАКТИРОВАТЬ

Только что проверил, что вы можете делать это только без my и no strict refs.

1 голос
/ 22 февраля 2010

Ответ Синан Юнур действительно лучший. Однако это вызвало у меня любопытство, поэтому я немного почитал (perldoc perlmod) и узнал о хеше «package_name ::» как способ доступа к пространству имен пакета.

Следующий код добавляет запись в таблицу символов main :: package: 

use strict;
my $name = "blah";
my $var = "sss";
$main::{$name} = \$var;

print "$main::blah\n";

Это печатает "sss".

Однако мне пришлось добавить имя пакета в оператор печати, потому что «использовать строгий» по-прежнему не одурачен. Я буду продолжать искать - использование vars, похоже, не работает в данный момент.

...