Ракетка URL рассылка - PullRequest
Новая
       10

Ракетка URL рассылка

7 голосов
/ 21 мая 2010

Я пытаюсь подключить рассылку URL с помощью Racket (ранее PLT Scheme). Я ознакомился с руководством и документацией к серверу. Я не могу понять, как перенаправлять запросы к одним и тем же сервлетам.

Конкретный пример: 

#lang scheme

(require web-server/servlet)
(require web-server/dispatch)
(provide/contract (start (request? . -> . response/c)))

(define (start request)
  (blog-dispatch request))

(define-values (blog-dispatch blog-url)
  (dispatch-rules
   (("") list-posts)
   (("posts" (string-arg)) review-post)
   (("archive" (integer-arg) (integer-arg)) review-archive)
   (else list-posts)))

(define (list-posts req) `(list-posts))
(define (review-post req p) `(review-post ,p))
(define (review-archive req y m) `(review-archive ,y ,m))

(require web-server/servlet-env)
(serve/servlet start
               #:launch-browser? #t
               #:quit? #f
               #:listen-ip #f
               #:port 8080
               #:extra-files-paths (list (build-path "js")
                                         (build-path "css"))
               #:servlet-path "")

Принимая код выше, localhost:8080/ переходит на страницу с надписью "list-posts". Переход на localhost:8080/posts/test приводит к странице "Файл не найден" в Racket (я ожидаю, что она перейдет на страницу с надписью "проверка после проверки").

Такое ощущение, что мне не хватает чего-то маленького и очевидного. Кто-нибудь может дать мне подсказку?

1 Ответ

12 голосов
/ 21 мая 2010

То, что вы написали, не является целой программой, поэтому я не могу отладить ее.

Вот программа с аннотациями, которая делает то, что вы хотите, вероятно: 

#lang scheme ; specify the right language
; include the correct libraries
(require web-server/servlet
         ; this one gets "serve/servlet"
         web-server/servlet-env)

(define (start request)
  (blog-dispatch request))

(define-values (blog-dispatch blog-url)
  (dispatch-rules
   (("") list-posts)
   (("posts" (string-arg)) review-post)
   (("archive" (integer-arg) (integer-arg)) review-archive)
   (else list-posts)))

(define (list-posts req) `(list-posts))
(define (review-post req p) `(review-post ,p))
(define (review-archive req y m) `(review-archive ,y ,m))

; starts a web server where...
(serve/servlet start ; answers requests
               #:servlet-path "" ; is the default URL
               #:port 8080 ; is the port
               #:servlet-regexp #rx"") ; is a regexp decide
                                       ; if 'start' should
                                       ; handle the request

Поскольку функции list-posts, review-post и review-archive не возвращают разумные xexpr-кодировки HTML, вам нужно просмотреть исходный код, чтобы увидеть их правильно.

Пожалуйста, не стесняйтесь, пишите мне напрямую или пишите в список рассылки Схемы PLT. (Примечание. Мы переименовываем схему PLT в «Racket», поэтому вы можете увидеть это при публикации).

Джей Маккарти

...