Могу ли я вытащить следующий элемент из цикла Perl Perl?

Question

Могу ли я сделать что-то вроде следующего в Perl?

foreach (@tokens) {
     if (/foo/){
       # simple case, I can act on the current token alone
       # do something
       next;
    }
    if (/bar/) {
       # now I need the next token, too
       # I want to read/consume it, advancing the iterator, so that
       # the next loop iteration will not also see it
       my $nextToken = .....
       # do something
       next;
    }

}

Обновление: Мне это нужно в Perl, но ради любопытства: есть ли в других языках аккуратный синтаксис для этого?

Answer 1

Вы должны использовать петлю for? Скопируйте оригинал и «используйте» его с помощью shift:

use strict;
use warnings;

my @original = 'a' .. 'z';    # Original
my @array = @original;        # Copy

while (my $token = shift @array) {

    shift @array if $token =~ /[nr]/; # consumes the next element
    print $token;
}

# prints 'abcdefghijklmnpqrtuvwxyz' ('s' and 'o' are missing)

Answer 2

Начиная с Perl 5.12, теперь стал более гибким , также работая с массивами:

use 5.012;
use warnings;

my @tokens = 'a' .. 'z';

while (my ($i, $val) = each @tokens) {
    if ($val =~ m/[aeiou]/) {
        ($i, $val) = each @tokens;   # get next token after a vowel
        print $val;
    }
}

# => bfjpv

Одно предупреждение с each, помните, что итератор является глобальным и не сбрасывается при выходе из цикла.

Например:

while (my ($i, $val) = each @tokens) {
    print $val;
    last if $i == 12;
}

# => abcdefghijklm

my ($i, $val) = each @tokens;
say "Now at => $val ($i)";         # Now at => n (13)

Поэтому используйте keys или values, чтобы вручную сбросить итератор:

keys @tokens;                      # resets iterator
($i, $val) = each @tokens;
say "Now at => $val ($i)";         # Now at => a (0)

Answer 3

Не с петлей foreach. Вы можете использовать цикл C-style for:

for (my $i = 0; $i <= $#tokens; ++$i) {
  local $_ = $tokens[$i];
  if (/foo/){
     next;
  }
  if (/bar/) {
    my $nextToken = $tokens[++$i];
    # do something
    next;
  }
}

Вы также можете использовать что-то вроде Array :: Iterator . Я оставлю эту версию в качестве упражнения для читателя. : -)

Answer 4

Мне нравится ответ Zaids, но он терпит неудачу, если встречает элемент nul в массиве, поэтому ...

while (@array) {

    my $token = shift @array;
    shift @array if $token =~ /[nr]/; # consumes the next element
    print $token;
} 

это не остановится, пока @array не станет пустым.