Конвейерная функция, вызывающая другую конвейерную функцию

Question

Вот пакет с двумя конвейерными функциями:

create or replace type tq84_line as table of varchar2(25);
/

create or replace package tq84_pipelined as

    function more_rows return tq84_line pipelined;
    function go        return tq84_line pipelined;

end tq84_pipelined;
/

В соответствующем корпусе упаковки:

create or replace package body tq84_pipelined as

    function more_rows return tq84_line pipelined is
    begin

        pipe row('ist');
        pipe row('Eugen,');

        return;

    end more_rows;

    function go return tq84_line pipelined is
    begin

        pipe row('Mein');
        pipe row('Name');

        /* start */
        for next in (
          select column_value line from table(more_rows)
        ) 
        loop
          pipe row(next.line);
        end loop;
        /* end */

        pipe row('ich');
        pipe row('weiss');
        pipe row('von');
        pipe row('nichts.');

    end go;

end tq84_pipelined;
/

Важно то, что вроде звонков more_rows с for next in ... между /* start */ и /* end */

Я могу использовать пакет следующим образом:

select * from table(tq84_pipelined.go);

Это все прекрасно, но я надеялся, что смогу заменить строки между /* start */ и /* end */ простым вызовом more_rows.

Однако это, очевидно, невозможно, так как он генерирует PLS-00221: «MORE_ROWS» не является процедурой или не определено .

Итак, мой вопрос: неужели нет способа сократить цикл?

EDIT

Очевидно, что из ответов до сих пор мой вопрос был неясен.

Пакет, как заявлено, работает.

Но меня беспокоит 6 (то есть: ШЕСТЬ) строк между маркерами /* start */ и /* end */. Я хотел бы заменить их одной строкой. Но я не нашел никакого способа сделать это.

Answer 1

Смысл конвейерных функций состоит в том, чтобы передавать функции TABLE (). Я не думаю, что есть способ избежать этого. К сожалению, мы должны присвоить его вывод переменной PL / SQL. Мы не можем назначить конвейерную функцию для вложенной таблицы, например, nt := more_rows; из-за

PLS-00653: aggregate/table functions are not allowed in PL/SQL scope

Так что SELECT ... FROM TABLE() должно быть.

У меня есть немного другое решение для вашего рассмотрения. Я не знаю, решает ли это вашу основную проблему.

create or replace package body tq84_pipelined as 

    function more_rows return tq84_line pipelined is 
    begin 

        pipe row('ist'); 
        pipe row('Eugen,'); 

        return; 

    end more_rows; 

    function go return tq84_line pipelined is 
        nt1 tq84_line;
        nt2 tq84_line;
        nt3 tq84_line;
        nt0 tq84_line;
    begin 

        nt1 := tq84_line('Mein','Name'); 

        select * 
        bulk collect into nt2
        from table(more_rows);

        nt3 := tq84_line('ich','weiss','von','nichts.'); 

        nt0 := nt1 multiset union nt2 multiset union nt3; 

        for i in nt0.first..nt0.last
        loop 
          pipe row(nt0(i)); 
        end loop; 

        return;

    end go; 

end tq84_pipelined; 
/

Как я уверен, вы знаете (но в интересах других искателей) синтаксис MULTISET UNION для блестящих коллекций был представлен в Oracle 10g.

Эта версия GO () выдает тот же вывод, что и исходная реализация:

SQL> select * from table( tq84_pipelined.go)
  2  /

COLUMN_VALUE
-------------------------
Mein
Name
ist
Eugen,
ich
weiss
von
nichts.

8 rows selected.

SQL>

Answer 2

Try select column_value line from table(tq84_line.more_rows) то есть включить имя запроса в запрос.