XPath "следуя за братьями и сестрами раньше" - PullRequest
Новая
       21

XPath "следуя за братьями и сестрами раньше"

3 голосов
/ 17 февраля 2010

Я пытаюсь выбрать элементы (a) с XPath 1.0 (или, возможно, с Regex), которые следуют за братьями и сестрами определенного элемента (b), но предшествуют только другому элементу b. 

<img><b>First</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/first-href">First Href</a> - 19:30<br>
<img><b>Second</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/second-href">Second Href</a> - 19:30<br>
<img>&nbsp;&nbsp;<a href="/third-href">Third Href</a> - 19:30<br>

Я пытался сделать образец как можно ближе к реальному миру. Так что в этом сценарии, когда я нахожусь на элементе 

<b>First</b>

Мне нужно выбрать 

<a href="/first-href">First Href</a>

и когда я нахожусь на 

<b>Second</b>

Мне нужно выбрать 

<a href="/second-href">Second Href</a> 
<a href="/third-href">Third Href</a>

Есть идеи, как этого добиться? Спасибо!

Ответы [ 2 ]

5 голосов
/ 17 февраля 2010

Динамически создайте этот XPath: 

following-sibling::a[preceding-sibling::b[1][.='xxxx']]

где 'xxxx' заменяется текстом текущего <b>.

Предполагается, что все элементы на самом деле являются родными элементами. Если это не так, вы можете попробовать работать с осями preceding и following или написать более конкретный XPath, который больше напоминает структуру документа.

В XSLT вы также можете использовать: 

following-sibling::a[
  generate-id(preceding-sibling::b[1]) = generate-id(current())
]
1 голос
/ 20 февраля 2010

Вот решение, представляющее собой только одно выражение XPath .

Использование формулы Кайса для пересечения двух наборов узлов $ns1 и $ns2: 

  $ns1[count(. | $ns2) = count($ns2)]

Мы просто заменим $ns1 набором узлов из <a> братьев и сестер, которые следуют за текущим <b> узлом, и заменим $ns2 набором узлов из <a> братьев и сестер, которые предшествуют следующему <b> узлу.

Вот полное преобразование, которое использует это : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="/">
   <xsl:apply-templates select="*/b"/>
  </xsl:template>

  <xsl:template match="b">
    At: <xsl:value-of select="."/>

    <xsl:variable name="vNextB" select="following-sibling::b[1]"/>

    <xsl:variable name="vA-sAfterCurrentB" select="following-sibling::a"/>

    <xsl:variable name="vA-sBeforeNextB" select=
    "$vNextB/preceding-sibling::a
    |
     $vA-sAfterCurrentB[not($vNextB)]
    "/>

    <xsl:copy-of select=
     "$vA-sAfterCurrentB
              [count(.| $vA-sBeforeNextB)
              =
               count($vA-sBeforeNextB)
               ]
    "/>
  </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к следующему документу XML : 

<t>
    <img/>
    <b>First</b>
    <br />&#xA0;&#xA0;
    <img/>&#xA0;&#xA0;
    <a href="/first-href">First Href</a> - 19:30
    <br />
    <img/>
    <b>Second</b>
    <br />
    <img/>&#xA0;&#xA0;
    <a href="/second-href">Second Href</a> - 19:30
    <br />
    <img/>&#xA0;
    <a href="/third-href">Third Href</a> - 19:30
    <br />
</t>

получен правильный результат : 

   At: First <a href="/first-href">First Href</a>
    At: Second <a href="/second-href">Second Href</a>
<a href="/third-href">Third Href</a>
...