XSL для отображения наибольшего количества копий в файле catalog.xml - PullRequest
Новая
       1

XSL для отображения наибольшего количества копий в файле catalog.xml

5 голосов
/ 20 марта 2010

В этом файле catalog.xml. У меня есть две книги с одинаковым инвентарем (т. Е. 20). Я хочу написать XSL-файл, который будет отображать наибольшее количество копий книги в каталоге. Если есть две или более книги одного и того же инвентаря, они должны быть показаны. 

<catalog>
  <Book>
    <sku>12345</sku>
    <title>Beauty Secrets</title>
    <condition>New</condition>
    <current_inventory>20</current_inventory>
    <price>99.99</price>
  </Book>
  <Book>
    <sku>54321</sku>
    <title>Picturescapes</title>
    <current_inventory>20</current_inventory>
    <condition>New</condition>
    <price>50.00</price>
  </Book> 
  <Book>
    <sku>33333</sku>
    <title>Tourist Perspectives</title>
    <condition>New</condition>
    <current_inventory>0</current_inventory>
    <price>75.00</price>
  </Book>
  <Book>
    <sku>10001</sku>
    <title>Fire in the Sky</title>
    <condition>Used</condition>
    <current_inventory>0</current_inventory>
    <price>10.00</price>
  </Book>
</catalog>

Ниже приведен мой catalog3.xsl файл, который может отображать только одну из двух книг: 

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:variable name="max"/>

  <xsl:template match="/">
    <html>
      <body>
        <h2>Titles of Books for which Most Copies are Available</h2>
        <table border="2">
          <tr bgcolor="#9acd32">
            <th>Title</th>
            <th>No of Copies</th>
          </tr>
          <xsl:apply-templates/>
        </table>
      </body>
    </html>
  </xsl:template>

  <xsl:template match="catalog">
    <xsl:for-each select="Book">
      <xsl:sort select="current_inventory" data-type="number" order="descending"/>
      <tr>
        <xsl:if test="position()= 1">
          <p><xsl:value-of select="$max = "/></p>
          <td><xsl:value-of select="title"/></td>
          <td><xsl:value-of select="current_inventory"/></td>
        </xsl:if>
      </tr>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

Может ли кто-нибудь поправить меня, чтобы достигнуть моей цели отображения всех копий, имеющих одинаковый максимальный запас в каталоге. Спасибо.

Ответы [ 4 ]

2 голосов
/ 22 марта 2010

Эта таблица стилей XSLT 1.0 

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
>
  <xsl:template match="catalog">
    <!-- find the maximum <current_inventory> of all books -->
    <xsl:variable name="MaxInventory">
      <xsl:for-each select="Book">
        <xsl:sort select="current_inventory" data-type="number" order="descending" />
        <xsl:if test="position() = 1">
          <xsl:value-of select="current_inventory" />
        </xsl:if>
      </xsl:for-each>
    </xsl:variable>

    <!-- output all matching <Book>s, sorted by title -->
    <table>
      <xsl:apply-templates select="Book[current_inventory = $MaxInventory]">
        <xsl:sort select="title" data-type="text" order="ascending" />
      </xsl:apply-templates>
    </table>
  </xsl:template>

  <xsl:template match="Book">
    <tr>
      <td><xsl:value-of select="title" /></td>
      <td><xsl:value-of select="current_inventory" /></td>
    </tr>
  </xsl:template>

</xsl:stylesheet>

производит 

<table>
  <tr>
    <td>Beauty Secrets</td>
    <td>20</td>
  </tr>
  <tr>
    <td>Picturescapes</td>
    <td>20</td>
  </tr>
</table>

Обратите внимание, что существует более эффективное решение, оно включает ключи XSL (это показывает Дмитрий Новатчев). Это простое и понятное решение для ключа XSL является передовым и играет свою «карту эффективности» только для больших входных документов (то есть тысяч книг). При небольших входных документах разница в производительности будет незначительной.

2 голосов
/ 20 марта 2010

Максимум current_inventory можно рассчитать следующим образом: 

<xsl:variable name="max">
  <xsl:for-each select="/catalog/Book/current_inventory">
    <xsl:sort data-type="number" order="descending"/>
    <xsl:if test="position()=1"><xsl:value-of select="."/></xsl:if>
  </xsl:for-each>
</xsl:variable>

Настройка критерия для xsl:if для сравнения current_inventory текущего узла в переменной for-each с переменной $max позволяет достичь желаемого результата.

Вы оценивали position()=1 внутри for-each, что будет верно только для первого элемента в отсортированной коллекции.

Я настроил его на поиск current_inventory, равный $max: 

<xsl:if test="current_inventory = $max">

Применение этих изменений к вашей таблице стилей : 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<!--Determine the maximum current_inventory -->
<xsl:variable name="max">
    <xsl:for-each select="/catalog/Book/current_inventory">
        <xsl:sort data-type="number" order="descending"/>
        <xsl:if test="position()=1"><xsl:value-of select="."/></xsl:if>
    </xsl:for-each>
</xsl:variable>

<xsl:template match="/">
    <html>
        <body>
            <h2>Titles of Books for which Most Copies are Available</h2>
            <table border="2">
                <tr bgcolor="#9acd32">
                    <th>Title</th>
                    <th>No of Copies</th>
                </tr>
                <xsl:apply-templates/>
            </table>
        </body>
    </html>
</xsl:template>
<xsl:template match="catalog">
    <xsl:for-each select="Book">
        <xsl:sort select="current_inventory" data-type="number" order="descending"/>

        <xsl:if test="current_inventory = $max">
                            <tr>
                <td>
                    <xsl:value-of select="title"/>
                </td>
                <td>
                    <xsl:value-of select="current_inventory"/>
                </td>
                            </tr>
        </xsl:if>

    </xsl:for-each>
</xsl:template>

2 голосов
/ 20 марта 2010

Вот решение с использованием мюнхенской группировки : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kBookByNums"
    match="Book" use="number(current_inventory)"/>

 <xsl:template match="/*">
   <xsl:for-each select=
    "Book
      [generate-id()
      =
       generate-id(key('kBookByNums',
                        number(current_inventory)
                       )[1]
                       )
       ]
    ">
     <xsl:sort select="current_inventory"
      data-type="number" order="descending"/>

      <xsl:if test="position()=1">
        <xsl:copy-of select=
          "key('kBookByNums',
                number(current_inventory)
               )"/>
      </xsl:if>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу, получается правильный результат : 

<Book>
<sku>12345</sku>
<title>Beauty Secrets</title>
<condition>New</condition>
<current_inventory>20</current_inventory>
<price>99.99</price>
</Book>
<Book>
<sku>54321</sku>
<title>Picturescapes</title>
<current_inventory>20</current_inventory>
<condition>New</condition>
<price>50.00</price>
</Book>

Обновление

Может показаться, что решение этого xsl-ключа «разыгрывает свою« карту эффективности »только для больших входных документов (то есть тысяч книг)», как кто-то сказал. На самом деле такое утверждение весьма неточно.

Улучшение эффективности может быть значительным, даже если элементов не так много , , если количество различных значений очень мало по сравнению с общим числом значений . Таким образом, даже для довольно небольших наборов элементов (одна-двести) существенный эффект имеет место, если число различных значений не превышает 10-20 - то, что происходит во многих реальных случаях.

Важное значение имеет малое отношение количества различных значений к общему размеру .

0 голосов
/ 20 марта 2010

С XSL такого рода вещи не интересны. Чтобы выяснить, «есть ли две или более книги одного и того же инвентаря» в разметке, когда количество инвентаря может быть произвольным, потребуется структура данных, в которой вы можете хранить количество обнаруженных запасов. Я бы предложил пересмотреть XML DOM до преобразования и рассчитать его (намного проще), а затем создать новый документ из узлов, которые вы хотите преобразовать, и применить к нему XSL. Это будет более простым и менее грязным, чем пытаться достичь всего в таблице стилей.

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...